Explicitly include compiler-rt builtins library in linking

This makes the intrinsic symbols contained within considered as strong
symbols, so that when the Rust stdlib intrinsics are marked as weak,
the C++ ones will take precedence. Otherwise, even if they are marked
weak, the Rust stdlib intrinsics are selected by the linker.

It may be the Rust intrinsics are preferable, but we want to stay on
the C++ intrinsics (for C++ and Rust code in mixed binaries) unless we
can demonstrate a good reason to switch.

Upstream bug for marking Rust intrinsic symbols weak:
rust-lang/compiler-builtins#525

To test and verify this works:
1. Revert the changes to shift.rs in rust-lang/compiler-builtins@1634193 to third_party/rust-toolchain/lib/rustlib/src/rust/vendor/compiler_builtins-*/src/int/shift.rs
2. Apply https://chromium-review.googlesource.com/c/chromium/src/+/45461823
3. Follow the instructions in its description to build and run bad_intrinsics
4. The bad_intrinsics binary panics without this CL, but not with this CL, meaning the C++ intrinsics are used.

Bug: 1445978
Change-Id: Ib251660346d03902f531285999aeeabc28882049
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/4546164
Commit-Queue: Arthur Eubanks <[email protected]>
Reviewed-by: Arthur Eubanks <[email protected]>
Auto-Submit: danakj <[email protected]>
Cr-Commit-Position: refs/heads/main@{#1150647}
NOKEYCHECK=True
GitOrigin-RevId: 31b9cb886d359780569bc5e1281bc7515d16e9bb

Author: danakj

config/compiler/BUILD.gn

@@ -1554,6 +1554,96 @@ config("compiler_arm") {
   }
 }
 
+# Rust and C++ both provide intrinsics for LLVM to call for math operations. We
+# want to use the C++ intrinsics, not the ones in the Rust compiler_builtins
+# library. The Rust symbols are marked as weak, so that they can be replaced by
+# the C++ symbols. This config ensures the C++ symbols exist and are strong in
+# order to cause that replacement to occur by explicitly linking in clang's
+# compiler-rt library.
+config("compiler_builtins") {
+  visibility = [ ":runtime_library" ]
+
+  _supported = true
+  _dir = ""
+  _libname = "builtins"
+  _suffix = ""
+  _ext = "a"
+  if (!toolchain_has_rust) {
+    # Since there's no Rust in the toolchain, there's no concern that we'll use
+    # the Rust stdlib's intrinsics here.
+    _supported = false
+  } else if (is_win) {
+    _dir = "windows"
+    _ext = "lib"
+    if (current_cpu == "x64") {
+      _suffix = "-x86_64"
+    } else if (current_cpu == "x86") {
+      _suffix = "-i386"
+    } else {
+      assert(false)  # Unhandled cpu type
+    }
+  } else if (is_mac) {
+    _dir = "darwin"
+    _libname = "osx"
+  } else if (is_ios) {
+    import("//build/config/ios/config.gni")  # For `target_environment`
+
+    _dir = "darwin"
+    if (target_environment == "simulator") {
+      _libname = "iossim"
+    } else {
+      _libname = "ios"
+    }
+  } else if (is_linux || is_chromeos) {
+    if (current_cpu == "x64") {
+      _dir = "x86_64-unknown-linux-gnu"
+    } else if (current_cpu == "x86") {
+      _dir = "i386-unknown-linux-gnu"
+    } else if (current_cpu == "arm") {
+      _dir = "armv7-unknown-linux-gnueabihf"
+    } else if (current_cpu == "arm64") {
+      _dir = "aarch64-unknown-linux-gnu"
+    } else {
+      assert(false)  # Unhandled cpu type
+    }
+  } else if (is_fuchsia) {
+    if (current_cpu == "x64") {
+      _dir = "x86_64-unknown-fuchsia"
+    } else if (current_cpu == "arm64") {
+      _dir = "aarch64-unknown-fuchsia"
+    } else {
+      assert(false)  # Unhandled cpu type
+    }
+  } else if (is_android) {
+    _dir = "linux"
+    if (current_cpu == "x64") {
+      _suffix = "-x86_64-android"
+    } else if (current_cpu == "x86") {
+      _suffix = "-i686-android"
+    } else if (current_cpu == "arm") {
+      _suffix = "-arm-android"
+    } else if (current_cpu == "arm64") {
+      _suffix = "-aarch64-android"
+    } else {
+      assert(false)  # Unhandled cpu type
+    }
+  } else {
+    assert(false)  # Unhandled target platform
+  }
+
+  if (_supported) {
+    _clang_lib_dir = "$clang_base_path/lib/clang/$clang_version/lib"
+    libs = [ "$_clang_lib_dir/$_dir/libclang_rt.$_libname$_suffix.$_ext" ]
+  } else {
+    not_needed([
+                 "_dir",
+                 "_libname",
+                 "_suffix",
+                 "_ext",
+               ])
+  }
+}
+
 # runtime_library -------------------------------------------------------------
 #
 # Sets the runtime library and associated options.
@@ -1575,6 +1665,10 @@ config("runtime_library") {
     configs += [ "//build/config/c++:runtime_library" ]
   }
 
+  if (toolchain_has_rust) {
+    configs += [ ":compiler_builtins" ]
+  }
+
   # TODO(crbug.com/830987): Come up with a better name for is POSIX + Fuchsia
   # configuration.
   if (is_posix || is_fuchsia) {