Separate properties module

pandas/_libs/lib.pyx

@@ -67,6 +67,7 @@ import tslib
 from tslib import NaT, Timestamp, Timedelta
 import interval
 from interval import Interval
+from properties import AxisProperty, cache_readonly  # noqa
 
 cdef int64_t NPY_NAT = util.get_nat()
 
@@ -1907,5 +1908,4 @@ cdef class BlockPlacement:
 
 
 include "reduce.pyx"
-include "properties.pyx"
 include "inference.pyx"

pandas/_libs/properties.pyx

@@ -0,0 +1,69 @@
+
+from cython cimport Py_ssize_t
+
+from cpython cimport (
+    PyDict_Contains, PyDict_GetItem, PyDict_SetItem)
+
+
+cdef class cache_readonly(object):
+
+    cdef readonly:
+        object func, name, allow_setting
+
+    def __init__(self, func=None, allow_setting=False):
+        if func is not None:
+            self.func = func
+            self.name = func.__name__
+        self.allow_setting = allow_setting
+
+    def __call__(self, func, doc=None):
+        self.func = func
+        self.name = func.__name__
+        return self
+
+    def __get__(self, obj, typ):
+        # Get the cache or set a default one if needed
+
+        cache = getattr(obj, '_cache', None)
+        if cache is None:
+            try:
+                cache = obj._cache = {}
+            except (AttributeError):
+                return
+
+        if PyDict_Contains(cache, self.name):
+            # not necessary to Py_INCREF
+            val = <object> PyDict_GetItem(cache, self.name)
+        else:
+            val = self.func(obj)
+            PyDict_SetItem(cache, self.name, val)
+        return val
+
+    def __set__(self, obj, value):
+
+        if not self.allow_setting:
+            raise Exception("cannot set values for [%s]" % self.name)
+
+        # Get the cache or set a default one if needed
+        cache = getattr(obj, '_cache', None)
+        if cache is None:
+            try:
+                cache = obj._cache = {}
+            except (AttributeError):
+                return
+
+        PyDict_SetItem(cache, self.name, value)
+
+cdef class AxisProperty(object):
+    cdef:
+        Py_ssize_t axis
+
+    def __init__(self, axis=0):
+        self.axis = axis
+
+    def __get__(self, obj, type):
+        cdef list axes = obj._data.axes
+        return axes[self.axis]
+
+    def __set__(self, obj, value):
+        obj._set_axis(self.axis, value)

setup.py

@@ -437,7 +437,7 @@ def get_tag(self):
     cmdclass['build_src'] = DummyBuildSrc
     cmdclass['build_ext'] = CheckingBuildExt
 
-lib_depends = ['reduce', 'inference', 'properties']
+lib_depends = ['reduce', 'inference']
 
 
 def srcpath(name=None, suffix='.pyx', subdir='src'):
@@ -478,6 +478,7 @@ def pxd(name):
 ext_data = {
     '_libs.lib': {'pyxfile': '_libs/lib',
                   'depends': lib_depends + tseries_depends},
+    '_libs.properties': {'pyxfile': '_libs/properties', 'include': []},
     '_libs.hashtable': {'pyxfile': '_libs/hashtable',
                         'pxdfiles': ['_libs/hashtable'],
                         'depends': (['pandas/_libs/src/klib/khash_python.h']