Add MissingDependenciesError exception

lib/elixir/lib/exception.ex

@@ -2131,6 +2131,38 @@ defmodule UnicodeConversionError do
   end
 end
 
+defmodule MissingApplicationsError do
+  @moduledoc """
+  An exception that is raised when there are one or more missing applications that some
+  application depends on.
+
+  This exception is used by Mix and other tools. It can also be used by library authors
+  when their library only requires an external application (like a dependency) for a subset
+  of features.
+
+  *Available since v1.18.0.*
+  """
+
+  @moduledoc since: "1.18.0"
+
+  @typedoc since: "1.18.0"
+  @type t() :: %__MODULE__{
+          apps: [{Application.app(), Version.requirement()}, ...]
+        }
+
+  defexception [:apps]
+
+  @impl true
+  def message(%__MODULE__{apps: apps}) do
+    formatted =
+      Enum.map(apps, fn {app, requirement} ->
+        "\n  * #{inspect(app)} (#{requirement})"
+      end)
+
+    "missing applications:\n#{formatted}\n"
+  end
+end
+
 defmodule Enum.OutOfBoundsError do
   @moduledoc """
   An exception that is raised when a function expects an enumerable to have

lib/elixir/test/elixir/exception_test.exs

@@ -954,6 +954,18 @@ defmodule ExceptionTest do
     test "ErlangError" do
       assert %ErlangError{original: :sample} |> message == "Erlang error: :sample"
     end
+
+    test "MissingApplicationsError" do
+      assert %MissingApplicationsError{
+               apps: [{:logger, "~> 1.18"}, {:ex_unit, Version.parse_requirement!(">= 0.0.0")}]
+             }
+             |> message == """
+             missing applications:
+
+               * :logger (~> 1.18)
+               * :ex_unit (>= 0.0.0)
+             """
+    end
   end
 
   describe "error_info" do