Refactor Video Library for STM32H7 boards

libraries/Arduino_H7_Video/examples/ArduinoLogo/ArduinoLogo.ino

@@ -0,0 +1,32 @@
+/*
+  ArduinoLogo
+
+  created 17 Apr 2023
+  by Leonardo Cavagnis
+*/
+
+#include "Arduino_H7_Video.h"
+
+#include "img_arduinologo.h"
+// Alternatively, any raw RGB565 image can be included on demand using this macro
+// Online image converter: https://lvgl.io/tools/imageconverter (Output format: Binary RGB565)
+/*
+#define INCBIN_PREFIX
+#include "incbin.h"
+INCBIN(test, "/home/user/Downloads/test.bin");
+*/
+
+Arduino_H7_Video Display(800, 480, GigaDisplayShield);
+//Arduino_H7_Video Display(1024, 768, USBCVideo);
+
+Image img_arduinologo(ENCODING_RGB16, (uint8_t *) texture_raw, 300, 300);
+
+void setup() {
+  Display.begin();
+
+  Display.beginDraw();
+  Display.image(img_arduinologo, (Display.width() - img_arduinologo.width())/2, (Display.height() - img_arduinologo.height())/2);
+  Display.endDraw();
+}
+
+void loop() { }

libraries/Arduino_H7_Video/examples/ArduinoLogoDrawing/ArduinoLogoDrawing.ino

@@ -0,0 +1,36 @@
+/*
+  ArduinoLogoDrawing
+
+  created 17 Apr 2023
+  by Leonardo Cavagnis
+*/
+
+#include "Arduino_H7_Video.h"
+
+Arduino_H7_Video Display(800, 480, GigaDisplayShield);
+//Arduino_H7_Video Display(1024, 768, USBCVideo);
+
+void setup() {
+  Display.begin();
+
+  Display.beginDraw();
+  Display.background(255, 255, 255);
+  Display.clear();
+  Display.fill(0x008184);
+  Display.circle(Display.width()/2, Display.height()/2, 300);
+  Display.stroke(255, 255, 255);
+  Display.noFill();
+  for (int i=0; i<30; i++) {
+    Display.circle((Display.width()/2)-55+5, Display.height()/2, 110-i);
+    Display.circle((Display.width()/2)+55-5, Display.height()/2, 110-i);
+  }
+  Display.fill(255, 255, 255);
+  Display.rect((Display.width()/2)-55-16+5, (Display.height()/2)-5, 32, 10);
+  Display.fill(255, 255, 255);
+  Display.rect((Display.width()/2)+55-16-5, (Display.height()/2)-5, 32, 10);
+  Display.fill(255, 255, 255);
+  Display.rect((Display.width()/2)+55-5-5, (Display.height()/2)-16, 10, 32);
+  Display.endDraw();
+}
+
+void loop() { }

libraries/Arduino_H7_Video/examples/LVGLDemo/LVGLDemo.ino

@@ -0,0 +1,56 @@
+
+/*
+  LVGLDemo
+
+  created 17 Apr 2023
+  by Leonardo Cavagnis
+*/
+
+#include "Arduino_H7_Video.h"
+
+#include "lvgl.h"
+#include "giga_touch.h"
+
+Arduino_H7_Video Display(800, 480, GigaDisplayShield);
+//Arduino_H7_Video Display(1024, 768, USBCVideo);
+
+void my_touchpad_read(lv_indev_drv_t * indev, lv_indev_data_t * data) {
+  data->state = (touchpad_pressed) ? LV_INDEV_STATE_PR : LV_INDEV_STATE_REL;
+  if(data->state == LV_INDEV_STATE_PR) {
+    data->point.x = giga_get_touch_x();
+    data->point.y = giga_get_touch_y();
+    touchpad_pressed = false;
+
+    Serial.print("Touch detected: ");
+    Serial.print(data->point.x);
+    Serial.print(",");
+    Serial.println(data->point.y);
+  }
+
+  return;
+}
+
+void setup() {
+  Serial.begin(115200);
+  giga_touch_setup();
+
+  Display.begin();
+  Display.attachLVGLTouchCb((void (*)(void*,void*))(my_touchpad_read));
+
+  /* Change the active screen's background color */
+  lv_obj_set_style_bg_color(lv_scr_act(), lv_color_hex(0x03989e), LV_PART_MAIN);
+
+  /* Create a white label, set its text and align it to the center */
+  lv_obj_t * label = lv_label_create(lv_scr_act());
+  lv_label_set_text(label, "Hello Arduino!");
+  lv_obj_set_style_text_color(lv_scr_act(), lv_color_hex(0xffffff), LV_PART_MAIN);
+  lv_obj_align(label, LV_ALIGN_CENTER, 0, 0);
+}
+
+void loop() { 
+  /* Touch handler */
+  giga_touch_handler();
+
+  /* Feed LVGL engine */
+  lv_timer_handler();
+}

libraries/Arduino_H7_Video/examples/LVGLDemo/giga_touch.cpp

@@ -0,0 +1,78 @@
+#include <Wire.h>
+#include "Goodix.h"  // Arduino_GT911_Library
+#include "pinDefinitions.h"
+
+Goodix touch = Goodix();
+
+REDIRECT_STDOUT_TO(Serial);
+
+#ifdef ARDUINO_GIGA
+#define Wire Wire1
+#define INT_PIN PinNameToIndex(PI_1)
+#define RST_PIN PinNameToIndex(PI_2)
+#endif
+
+#ifdef ARDUINO_PORTENTA_H7_M7
+#define INT_PIN PinNameToIndex(PD_4)
+#define RST_PIN PinNameToIndex(PD_5)
+#endif
+
+uint16_t touchpad_x;
+uint16_t touchpad_y;
+bool touchpad_pressed;
+
+void handleTouch(int8_t contacts, GTPoint *points) {
+  touchpad_pressed = true;
+  //printf("Contacts: %d\n", contacts);
+  for (uint8_t i = 0; i < contacts; i++) {
+    if (i == 0) {
+      touchpad_x = points[i].x;
+      touchpad_y = points[i].y;
+    }
+    //printf("C%d: #%d %d,%d s:%d\n", i, points[i].trackId, points[i].x, points[i].y, points[i].area);
+    yield();
+  }
+}
+
+void touchStart() {
+  if (touch.begin(Wire, INT_PIN, RST_PIN, 0xDD) != true) {
+    Serial.println("! Module reset failed");
+  } else {
+    Serial.println("Module reset OK");
+  }
+
+  Serial.print("Check ACK on addr request on 0x");
+  Serial.print(touch.i2cAddr, HEX);
+
+  Wire.beginTransmission(touch.i2cAddr);
+  Wire.write(0);
+  int error = Wire.endTransmission();
+  if (error == 0) {
+    Serial.println(": SUCCESS");
+  } else {
+    Serial.print(": ERROR #");
+    Serial.println(error);
+  }
+}
+
+void giga_touch_setup() {
+  Wire.setClock(400000);
+  Wire.begin();
+  delay(300);
+
+  touch.setHandler(handleTouch);
+  touchStart();
+}
+
+void giga_touch_handler() {
+  touch.loop();
+  delay(1);
+}
+
+uint16_t giga_get_touch_x() {
+  return touchpad_x;
+}
+
+uint16_t giga_get_touch_y() {
+  return touchpad_y;
+}

libraries/Arduino_H7_Video/examples/LVGLDemo/giga_touch.h

@@ -0,0 +1,7 @@
+void giga_touch_setup();
+void giga_touch_handler();
+
+uint16_t giga_get_touch_x();
+uint16_t giga_get_touch_y();
+
+extern bool touchpad_pressed;

libraries/Portenta_Video/library.properties → libraries/Arduino_H7_Video/library.properties

@@ -1,9 +1,9 @@
-name=Portenta_Video
+name=Arduino_H7_Video
 version=1.0
 author=Arduino
 maintainer=Arduino <[email protected]>
-sentence=video primitives for Portenta H7 via USBC (to HDMI adapter)
+sentence=video primitives for Portenta H7 and Giga R1
 paragraph=
 category=Display
-url=https://github.com/arduino/ArduinoCore-mbed/tree/master/libraries/Portenta_Video
+url=https://github.com/arduino/ArduinoCore-mbed/tree/master/libraries/Arduino_H7_Video
 architectures=mbed,mbed_portenta,mbed_giga