Adding pushRawData:

pushRawData allows (e.g.) RTCM data to be pushed directly to the module
Tested with updated versions of the ZED-F9P Example3 (RTCM base) and Example5 (Relative Positioning)

Author: PaulZC

Diff for: examples/ZED-F9P/Example3_StartRTCMBase/Example3_StartRTCMBase.ino

@@ -29,12 +29,19 @@
 #include "SparkFun_Ublox_Arduino_Library.h" //http://librarymanager/All#SparkFun_Ublox_GPS
 SFE_UBLOX_GPS myGPS;
 
+//#define USE_SERIAL1 // Uncomment this line to push the RTCM data to Serial1
+
 void setup()
 {
   Serial.begin(115200);
   while (!Serial); //Wait for user to open terminal
   Serial.println("Ublox Base station example");
 
+#ifdef USE_SERIAL1
+  // If our board supports it, we can output the RTCM data on Serial1
+  Serial1.begin(115200);
+#endif
+
   Wire.begin();
   Wire.setClock(400000); //Increase I2C clock speed to 400kHz
 
@@ -44,8 +51,11 @@ void setup()
     while (1);
   }
 
+  // Uncomment the next line if you want to reset your module back to the default settings with 1Hz navigation rate
+  //myGPS.factoryDefault(); delay(5000);
+
   myGPS.setI2COutput(COM_TYPE_UBX); //Set the I2C port to output UBX only (turn off NMEA noise)
-  myGPS.saveConfiguration(); //Save the current settings to flash and BBR
+  myGPS.saveConfigSelective(VAL_CFG_SUBSEC_IOPORT); //Save the communications port settings to flash and BBR
 
   while (Serial.available()) Serial.read(); //Clear any latent chars in serial buffer
   Serial.println("Press any key to send commands to begin Survey-In");
@@ -153,7 +163,12 @@ void loop()
 //Useful for passing the RTCM correction data to a radio, Ntrip broadcaster, etc.
 void SFE_UBLOX_GPS::processRTCM(uint8_t incoming)
 {
-  //Let's just pretty-print the HEX values for now
+#ifdef USE_SERIAL1
+  //Push the RTCM data to Serial1
+  Serial1.write(incoming);
+#endif
+
+  //Pretty-print the HEX values to Serial
   if (myGPS.rtcmFrameCounter % 16 == 0) Serial.println();
   Serial.print(" ");
   if (incoming < 0x10) Serial.print("0");

Diff for: examples/ZED-F9P/Example5_RelativePositioningInformation/Example5_RelativePositioningInformation.ino

@@ -26,12 +26,21 @@
 #include "SparkFun_Ublox_Arduino_Library.h" //http://librarymanager/All#SparkFun_Ublox_GPS
 SFE_UBLOX_GPS myGPS;
 
+//#define USE_SERIAL1 // Uncomment this line to push the RTCM data from Serial1 to the module via I2C
+
+size_t numBytes = 0; // Record the number os bytes received from Serial1
+
 void setup()
 {
   Serial.begin(115200);
   while (!Serial); //Wait for user to open terminal
   Serial.println("Ublox Base station example");
 
+#ifdef USE_SERIAL1
+  // If our board supports it, we can receive the RTCM data on Serial1
+  Serial1.begin(115200);
+#endif
+
   Wire.begin();
   Wire.setClock(400000); //Increase I2C clock speed to 400kHz
 
@@ -40,6 +49,15 @@ void setup()
     Serial.println(F("Ublox GPS not detected at default I2C address. Please check wiring. Freezing."));
     while (1);
   }
+
+  // Uncomment the next line if you want to reset your module back to the default settings with 1Hz navigation rate
+  //myGPS.factoryDefault(); delay(5000);
+
+#ifdef USE_SERIAL1
+  Serial.print(F("Enabling UBX and RTCM input on I2C. Result: "));
+  Serial.print(myGPS.setPortInput(COM_PORT_I2C, COM_TYPE_UBX | COM_TYPE_RTCM3)); //Enable UBX and RTCM input on I2C
+  myGPS.saveConfigSelective(VAL_CFG_SUBSEC_IOPORT); //Save the communications port settings to flash and BBR
+#endif
 }
 
 void loop()
@@ -121,5 +139,23 @@ void loop()
   else
     Serial.println("RELPOS request failed");
 
-  delay(4000);
+  for (int i = 0; i < 500; i++)
+  {
+#ifdef USE_SERIAL1
+    uint8_t store[256];
+    while ((Serial1.available()) && (numBytes < 256)) // Check if data has been received
+    {
+      store[numBytes++] = Serial1.read(); // Read a byte from Serial1 and store it
+    }
+    if (numBytes > 0) // Check if data was received
+    {
+      //Serial.print("Pushing ");
+      //Serial.print(numBytes);
+      //Serial.println(" bytes via I2C");
+      myGPS.pushRawData(((uint8_t *)&store), numBytes); // Push the RTCM data via I2C
+      numBytes = 0; // Reset numBytes
+    }
+#endif
+    delay(10);
+  }
 }

Diff for: keywords.txt

@@ -173,6 +173,8 @@ getI2CTransactionSize	KEYWORD2
 
 setStaticPosition   KEYWORD2
 
+pushRawData   KEYWORD2
+
 #######################################
 # Constants (LITERAL1)
 #######################################

Diff for: src/SparkFun_Ublox_Arduino_Library.cpp

@@ -4197,3 +4197,51 @@ bool SFE_UBLOX_GPS::setStaticPosition(int32_t ecefXOrLat, int32_t ecefYOrLon, in
 {
   return (setStaticPosition(ecefXOrLat, 0, ecefYOrLon, 0, ecefZOrAlt, 0, latlong, maxWait));
 }
+
+// Push (e.g.) RTCM data directly to the module
+// Returns true if all numDataBytes were pushed successfully
+// Warning: this function does not check that the data is valid. It is the user's responsibility to ensure the data is valid before pushing.
+boolean SFE_UBLOX_GPS::pushRawData(uint8_t *dataBytes, size_t numDataBytes)
+{
+  if (commType == COMM_TYPE_SERIAL)
+  {
+    // Serial: write all the bytes in one go
+    size_t bytesWritten = _serialPort->write(dataBytes, numDataBytes);
+    return (bytesWritten == numDataBytes);
+  }
+  else
+  {
+    // I2C: split the data up into packets of i2cTransactionSize
+    size_t bytesLeftToWrite = numDataBytes;
+    size_t bytesWrittenTotal = 0;
+
+    while (bytesLeftToWrite > 0)
+    {
+      size_t bytesToWrite; // Limit bytesToWrite to i2cTransactionSize
+      if (bytesLeftToWrite > i2cTransactionSize)
+        bytesToWrite = i2cTransactionSize;
+      else
+        bytesToWrite = bytesLeftToWrite;
+
+      _i2cPort->beginTransmission(_gpsI2Caddress);
+      size_t bytesWritten = _i2cPort->write(dataBytes, bytesToWrite); // Write the bytes
+
+      bytesWrittenTotal += bytesWritten; // Update the totals
+      bytesLeftToWrite -= bytesToWrite;
+      dataBytes += bytesToWrite; // Point to fresh data
+
+      if (bytesLeftToWrite > 0)
+      {
+        if (_i2cPort->endTransmission(false) != 0) //Send a restart command. Do not release bus.
+          return (false);                          //Sensor did not ACK
+      }
+      else
+      {
+        if (_i2cPort->endTransmission() != 0) //We're done. Release bus.
+          return (false);                     //Sensor did not ACK
+      }
+    }
+
+    return (bytesWrittenTotal == numDataBytes);
+  }
+}

Diff for: src/SparkFun_Ublox_Arduino_Library.h

@@ -666,6 +666,10 @@ class SFE_UBLOX_GPS
 	bool setStaticPosition(int32_t ecefXOrLat, int8_t ecefXOrLatHP, int32_t ecefYOrLon, int8_t ecefYOrLonHP, int32_t ecefZOrAlt, int8_t ecefZOrAltHP, bool latLong = false, uint16_t maxWait = 250);
 	bool setStaticPosition(int32_t ecefXOrLat, int32_t ecefYOrLon, int32_t ecefZOrAlt, bool latLong = false, uint16_t maxWait = 250);
 
+	// Push (e.g.) RTCM data directly to the module
+	// Warning: this function does not check that the data is valid. It is the user's responsibility to ensure the data is valid before pushing.
+	boolean pushRawData(uint8_t *dataBytes, size_t numDataBytes);
+
 	//Survey-in specific controls
 	struct svinStructure
 	{