Deduplicate nix code

And clean it up a little.

Author: RossSmyth

Diff for: result

@@ -0,0 +1 @@
+/nix/store/in1pq3wd1sm6ylnxy2q6aw19gb3h650r-x-none

Diff for: src/tools/nix-dev-shell/flake.nix

@@ -1,32 +1,19 @@
 {
   description = "rustc dev shell";
 
-  inputs = {
-    nixpkgs.url      = "github:NixOS/nixpkgs/nixos-unstable";
-    flake-utils.url  = "github:numtide/flake-utils";
-  };
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
 
-  outputs = { self, nixpkgs, flake-utils, ... }:
-	flake-utils.lib.eachDefaultSystem (system:
-      let
-        pkgs = import nixpkgs { inherit system; };
-        x = import ./x { inherit pkgs; };
-      in
-      {
-        devShells.default = with pkgs; mkShell {
-          name = "rustc-dev-shell";
-          nativeBuildInputs = with pkgs; [
-            binutils cmake ninja pkg-config python3 git curl cacert patchelf nix
-          ];
-          buildInputs = with pkgs; [
-            openssl glibc.out glibc.static x
-          ];
-          # Avoid creating text files for ICEs.
-          RUSTC_ICE = "0";
-          # Provide `libstdc++.so.6` for the self-contained lld.
-          # Provide `libz.so.1`.
-          LD_LIBRARY_PATH = "${with pkgs; lib.makeLibraryPath [stdenv.cc.cc.lib zlib]}";
-        };
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    inherit (nixpkgs) lib;
+    forEachSystem = lib.genAttrs lib.systems.flakeExposed;
+  in {
+    devShells = forEachSystem (
+      system: {
+        default = nixpkgs.legacyPackages.${system}.callPackage ./shell.nix {};
       }
     );
+  };
 }

Diff for: src/tools/nix-dev-shell/shell.nix

@@ -1,18 +1,35 @@
-{ pkgs ? import <nixpkgs> {} }:
-let 
-  x = import ./x { inherit pkgs; };
+{pkgs ? import <nixpkgs> {}}: let
+  x = pkgs.callPackage ./x {};
 in
-pkgs.mkShell {
-  name = "rustc";
-  nativeBuildInputs = with pkgs; [
-    binutils cmake ninja pkg-config python3 git curl cacert patchelf nix
-  ];
-  buildInputs = with pkgs; [
-    openssl glibc.out glibc.static x
-  ];
-  # Avoid creating text files for ICEs.
-  RUSTC_ICE = "0";
-  # Provide `libstdc++.so.6` for the self-contained lld.
-  # Provide `libz.so.1`
-  LD_LIBRARY_PATH = "${with pkgs; lib.makeLibraryPath [stdenv.cc.cc.lib zlib]}";
-}
+  pkgs.mkShell {
+    strictDeps = true;
+    pname = "rustc-shell";
+    version = "none";
+
+    packages = let
+      p = pkgs;
+    in [
+      p.binutils
+      p.cmake
+      p.ninja
+      p.pkg-config
+      p.python3
+      p.git
+      p.curl
+      p.cacert
+      p.patchelf
+      p.nix
+      p.openssl.dev
+      p.glibc.out
+      p.glibc.static
+      x
+    ];
+
+    env = {
+      # Avoid creating text files for ICEs.
+      RUSTC_ICE = 0;
+      # Provide `libstdc++.so.6` for the self-contained lld.
+      # Provide `libz.so.1`
+      LD_LIBRARY_PATH = let p = pkgs; in p.lib.makeLibraryPath [p.stdenv.cc.cc.lib p.zlib];
+    };
+  }

Diff for: src/tools/nix-dev-shell/x/default.nix

@@ -1,22 +1,29 @@
 {
-  pkgs ? import <nixpkgs> { },
+  pkgs,
+  lib,
+  stdenv,
+  rustc,
+  python3,
 }:
-pkgs.stdenv.mkDerivation {
-  name = "x";
+stdenv.mkDerivation {
+  strictDeps = true;
+  pname = "x";
+  version = "none";
 
   src = ./x.rs;
   dontUnpack = true;
 
-  nativeBuildInputs = with pkgs; [ rustc ];
+  nativeBuildInputs = [rustc];
 
+  env.PYTHON = lib.getExe python3;
   buildPhase = ''
-    PYTHON=${pkgs.lib.getExe pkgs.python3} rustc -Copt-level=3 --crate-name x $src --out-dir $out/bin
+    rustc -Copt-level=3 --crate-name x $src --out-dir $out/bin
   '';
 
-  meta = with pkgs.lib; {
+  meta = {
     description = "Helper for rust-lang/rust x.py";
     homepage = "https://github.com/rust-lang/rust/blob/master/src/tools/x";
-    license = licenses.mit;
+    license = lib.licenses.mit;
     mainProgram = "x";
   };
 }