Add python3-hatchling (from meta-oe)

Recipes in core are now needing to use the Hatch build system, so
move the hatchling recipe and class from meta-oe to oe-core.

Signed-off-by: Ross Burton <[email protected]>
Signed-off-by: Luca Ceresoli <[email protected]>
Signed-off-by: Richard Purdie <[email protected]>

Author: rossburton

meta/classes/python_hatchling.bbclass

@@ -0,0 +1,5 @@
+inherit python_pep517 python3native python3-dir setuptools3-base
+
+DEPENDS += "python3-hatchling-native"
+
+PEP517_BUILD_API = "hatchling.build"

meta/conf/distro/include/maintainers.inc

@@ -612,6 +612,7 @@ RECIPE_MAINTAINER:pn-python3-extras = "Oleksandr Kravchuk <open.source@oleksandr
 RECIPE_MAINTAINER:pn-python3-flit-core = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-git = "Oleksandr Kravchuk <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-gitdb = "Oleksandr Kravchuk <[email protected]>"
+RECIPE_MAINTAINER:pn-python3-hatchling = "Ross Burton <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-hypothesis = "Tim Orling <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-idna = "Bruce Ashfield <[email protected]>"
 RECIPE_MAINTAINER:pn-python3-imagesize = "Tim Orling <[email protected]>"

meta/recipes-devtools/python/python3-hatchling_1.3.0.bb

@@ -0,0 +1,21 @@
+SUMMARY = "The extensible, standards compliant build backend used by Hatch"
+HOMEPAGE = "https://hatch.pypa.io/"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=cbe2fd33fc9297692812fc94b7d27fd9"
+
+inherit pypi python_hatchling
+
+DEPENDS += "python3-pluggy-native python3-tomli-native python3-pathspec-native python3-packaging-native python3-editables-native"
+DEPENDS:remove:class-native = "python3-hatchling-native"
+
+SRC_URI[sha256sum] = "1401d45d3dd6a5910f64d539acaa943486d5e8b7dda1a97f2b0040fdddc5b85e"
+
+# Until we have a proper tool to invoke PEP517 builds, hatchling can't
+# bootstrap itself automatically.
+PEP517_BUILD_API = "hatchling.ouroboros"
+
+do_compile:prepend() {
+    export PYTHONPATH=src
+}
+
+BBCLASSEXTEND = "native nativesdk"