Move C++ constructor and destructor tables and .bss to .irom0 (flash)

Author: TAiGA

tools/sdk/ld/eagle.app.v6.common.ld.h

@@ -162,6 +162,24 @@ SECTIONS
     *(.rodata._ZTV*) /* C++ vtables */
 #endif
 
+    . = ALIGN(4);       /* this table MUST be 4-byte aligned */
+    /*  C++ constructor and destructor tables, properly ordered:  */
+    __init_array_start = ABSOLUTE(.);
+    KEEP (*crtbegin.o(.ctors))
+    KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
+    KEEP (*(SORT(.ctors.*)))
+    KEEP (*(.ctors))
+    __init_array_end = ABSOLUTE(.);
+    KEEP (*crtbegin.o(.dtors))
+    KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
+    KEEP (*(SORT(.dtors.*)))
+    KEEP (*(.dtors))
+    . = ALIGN(4);       /* this table MUST be 4-byte aligned */
+    _bss_table_start = ABSOLUTE(.);
+    LONG(_bss_start)
+    LONG(_bss_end)
+    _bss_table_end = ABSOLUTE(.);
+
     *libgcc.a:unwind-dw2.o(.literal .text .rodata .literal.* .text.* .rodata.*)
     *libgcc.a:unwind-dw2-fde.o(.literal .text .rodata .literal.* .text.* .rodata.*)
 
@@ -229,6 +247,36 @@ SECTIONS
     /* Fundamental type info */
     *(.rodata._ZTIPKc .rodata._ZTIc .rodata._ZTIv .rodata._ZTSv .rodata._ZTSc .rodata._ZTSPKc .rodata._ZTSi .rodata._ZTIi)
 
+    /* std::make_shared */
+    *(.rodata._ZZNSt19_Sp_make_shared_tag5_S_tiEvE5__tag)
+
+#ifdef FREE_MORE_DRAM
+    *(.sdk.version)
+    *libc.a:lib_a-dtoa.o                (.rodata .rodata.*)
+    *libc.a:lib_a-gdtoa-gethex.o        (.rodata .rodata.*)
+    *libc.a:lib_a-impure.o              (.rodata .rodata.*)
+    *libc.a:lib_a-lcltime.o             (.rodata .rodata.*)
+    *libc.a:lib_a-lnumeric.o            (.rodata .rodata.*)
+    *libc.a:lib_a-locale.o              (.rodata .rodata.* .data)
+    *libc.a:lib_a-mprec.o               (.rodata .rodata.*)
+    *libc.a:lib_a-nano-svfprintf.o      (.rodata .rodata.*)
+    *libc.a:lib_a-nano-svfscanf.o       (.rodata .rodata.*)
+    *libc.a:lib_a-nano-vfprintf_float.o (.rodata .rodata.*)
+    *libc.a:lib_a-nano-vfprintf.o       (.rodata .rodata.*)
+    *libc.a:lib_a-nano-vfscanf_float.o  (.rodata .rodata.*)
+    *libc.a:lib_a-nano-vfscanf_i.o      (.rodata .rodata.*)
+    *libc.a:lib_a-rand.o                (.rodata .rodata.*)
+    *libc.a:lib_a-strtod.o              (.rodata .rodata.*)
+    *libc.a:lib_a-tzset_r.o             (.rodata .rodata.*)
+    *libc.a:lib_a-tzvars.o              (.rodata .rodata.*)
+    *liblwip2-536.a:                    (.rodata .rodata.memp_pools .rodata.tcp_pcb_lists .rodata.dns_mquery_v4group .rodata.ip_addr_broadcast .rodata.ip_addr_any)
+    *liblwip2-1460.a:                   (.rodata .rodata.memp_pools .rodata.tcp_pcb_lists .rodata.dns_mquery_v4group .rodata.ip_addr_broadcast .rodata.ip_addr_any)
+    *libnet80211.a:ieee80211_input.o    (.rodata .rodata.* .data)
+    *libnet80211.a:ieee80211_scan.o     (.rodata .rodata.* .data)
+    *libphy.a:phy_chip_v6.o             (.rodata .rodata.*)
+    *libpp.a:esf_buf.o                  (.rodata .rodata.*)
+#endif
+
     . = ALIGN(4);
     *(.gcc_except_table .gcc_except_table.*)
     . = ALIGN(4);

tools/sdk/ld/eagle.app.v6.common.ld.vtables.h

@@ -12,18 +12,7 @@
     *(.gnu.linkonce.e.*)
     *(.gnu.version_r)
     *(.eh_frame)
-    . = (. + 3) & ~ 3;
-    /*  C++ constructor and destructor tables, properly ordered:  */
-    __init_array_start = ABSOLUTE(.);
-    KEEP (*crtbegin.o(.ctors))
-    KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
-    KEEP (*(SORT(.ctors.*)))
-    KEEP (*(.ctors))
-    __init_array_end = ABSOLUTE(.);
-    KEEP (*crtbegin.o(.dtors))
-    KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
-    KEEP (*(SORT(.dtors.*)))
-    KEEP (*(.dtors))
+    . = ALIGN(4);
     /*  C++ exception handlers table:  */
     __XT_EXCEPTION_DESCS__ = ABSOLUTE(.);
     *(.xt_except_desc)
@@ -32,11 +21,6 @@
     *(.xt_except_desc_end)
     *(.dynamic)
     *(.gnu.version_d)
-    . = ALIGN(4);       /* this table MUST be 4-byte aligned */
-    _bss_table_start = ABSOLUTE(.);
-    LONG(_bss_start)
-    LONG(_bss_end)
-    _bss_table_end = ABSOLUTE(.);
     _rodata_end = ABSOLUTE(.);
   } >dram0_0_seg :dram0_0_phdr