Merge pull request #1796 from firebase/firestore-protos-master

Author: wilhuff

CMakeLists.txt

@@ -176,13 +176,12 @@ endif()
 
 # nanopb
 set(nanopb_BUILD_GENERATOR ON CACHE BOOL "Enable the nanopb generator")
-set(nanopb_PROTOC_PATH ${NANOPB_PROTOC_BIN} CACHE STRING "Protoc location")
 set(nanopb_MSVC_STATIC_RUNTIME OFF CACHE BOOL "Link static runtime libraries")
 add_external_subdirectory(nanopb)
 
 target_compile_definitions(
   protobuf-nanopb
-  PUBLIC -DPB_FIELD_16BIT
+  PUBLIC -DPB_FIELD_32BIT -DPB_ENABLE_MALLOC
 )
 
 target_include_directories(

Firestore/Protos/CMakeLists.txt

@@ -12,43 +12,89 @@
 # See the License for the specific language governing permissions and
 # limitations under the License.
 
+# Generate output in-place. So long as the build is idempotent this helps
+# verify that the protoc-generated output isn't changing.
+set(OUTPUT_DIR ${CMAKE_CURRENT_SOURCE_DIR})
+
+# Filename "roots" (i.e. without the .proto) from within the proto directory,
+# excluding anything in google/protobuf.
+set(
+  PROTO_FILE_ROOTS
+  firestore/local/maybe_document
+  firestore/local/mutation
+  firestore/local/target
+  google/api/annotations
+  google/api/http
+  google/firestore/v1beta1/common
+  google/firestore/v1beta1/document
+  google/firestore/v1beta1/firestore
+  google/firestore/v1beta1/query
+  google/firestore/v1beta1/write
+  google/rpc/status
+  google/type/latlng
+)
+
+# Filename "roots" (i.e. without the .proto) from within the proto directory,
+# from the google/protobuf package.
+set(
+  WELL_KNOWN_PROTO_FILE_ROOTS
+  google/protobuf/any
+  google/protobuf/empty
+  google/protobuf/struct
+  google/protobuf/timestamp
+  google/protobuf/wrappers
+)
+
+# Populate NANOPB_GENERATED_SOURCES with the list of nanopb-generated sources.
+# The nanopb runtime does not include the well-known protos so we have to build
+# them ourselves.
+foreach(root ${PROTO_FILE_ROOTS} ${WELL_KNOWN_PROTO_FILE_ROOTS})
+  list(
+    APPEND NANOPB_GENERATED_SOURCES
+    ${OUTPUT_DIR}/nanopb/${root}.nanopb.c
+    ${OUTPUT_DIR}/nanopb/${root}.nanopb.h
+  )
+endforeach()
+
+# Populate PROTOBUF_CPP_GENERATED_SOURCES with the list of libprotobuf C++
+# sources. These are used for verifying interoperation from nanopb.
+#
+# Libprotobuf includes the well-known protos so they must be omitted here.
+foreach(root ${PROTO_FILE_ROOTS})
+  list(
+    APPEND PROTOBUF_CPP_GENERATED_SOURCES
+    ${OUTPUT_DIR}/cpp/${root}.pb.cc
+    ${OUTPUT_DIR}/cpp/${root}.pb.h
+  )
+endforeach()
+
+# Populate PROTOBUF_OBJC_GENERATED_SOURCES with the list of libprotobuf
+# Objective-C sources. These are used by the old Objective-C implementation
+# that we're replacing.
+#
+# Libprotobuf Objective-C also includes the well-known protos so they must be
+# omitted here.
+#
+# The Objective-C client also uses the generated gRPC stubs for the Firestore
+# service.
+set(
+  PROTOBUF_OBJC_GENERATED_SOURCES
+  ${OUTPUT_DIR}/objc/google/firestore/v1beta1/Firestore.pbrpc.h
+  ${OUTPUT_DIR}/objc/google/firestore/v1beta1/Firestore.pbrpc.m
+)
+foreach(root ${PROTO_FILE_ROOTS})
+  list(
+    APPEND PROTOBUF_OBJC_GENERATED_SOURCES
+    ${OUTPUT_DIR}/objc/${root}.pbobjc.h
+    ${OUTPUT_DIR}/objc/${root}.pbobjc.m
+  )
+endforeach()
+
+
 cc_library(
   firebase_firestore_protos_nanopb
   SOURCES
-    nanopb/firestore/local/maybe_document.pb.c
-    nanopb/firestore/local/maybe_document.nanopb.h
-    nanopb/firestore/local/mutation.pb.c
-    nanopb/firestore/local/mutation.nanopb.h
-    nanopb/firestore/local/target.pb.c
-    nanopb/firestore/local/target.nanopb.h
-    nanopb/google/api/annotations.pb.c
-    nanopb/google/api/annotations.nanopb.h
-    nanopb/google/api/http.pb.c
-    nanopb/google/api/http.nanopb.h
-    nanopb/google/firestore/v1beta1/common.pb.c
-    nanopb/google/firestore/v1beta1/common.nanopb.h
-    nanopb/google/firestore/v1beta1/document.pb.c
-    nanopb/google/firestore/v1beta1/document.nanopb.h
-    nanopb/google/firestore/v1beta1/firestore.pb.c
-    nanopb/google/firestore/v1beta1/firestore.nanopb.h
-    nanopb/google/firestore/v1beta1/query.pb.c
-    nanopb/google/firestore/v1beta1/query.nanopb.h
-    nanopb/google/firestore/v1beta1/write.pb.c
-    nanopb/google/firestore/v1beta1/write.nanopb.h
-    nanopb/google/protobuf/any.pb.c
-    nanopb/google/protobuf/any.nanopb.h
-    nanopb/google/protobuf/empty.pb.c
-    nanopb/google/protobuf/empty.nanopb.h
-    nanopb/google/protobuf/struct.pb.c
-    nanopb/google/protobuf/struct.nanopb.h
-    nanopb/google/protobuf/timestamp.pb.c
-    nanopb/google/protobuf/timestamp.nanopb.h
-    nanopb/google/protobuf/wrappers.pb.c
-    nanopb/google/protobuf/wrappers.nanopb.h
-    nanopb/google/rpc/status.pb.c
-    nanopb/google/rpc/status.nanopb.h
-    nanopb/google/type/latlng.pb.c
-    nanopb/google/type/latlng.nanopb.h
+    ${NANOPB_GENERATED_SOURCES}
   DEPENDS
     protobuf-nanopb
 )
@@ -64,30 +110,7 @@ target_include_directories(
 cc_library(
   firebase_firestore_protos_libprotobuf
   SOURCES
-    cpp/firestore/local/maybe_document.pb.cc
-    cpp/firestore/local/maybe_document.pb.h
-    cpp/firestore/local/mutation.pb.cc
-    cpp/firestore/local/mutation.pb.h
-    cpp/firestore/local/target.pb.cc
-    cpp/firestore/local/target.pb.h
-    cpp/google/api/annotations.pb.cc
-    cpp/google/api/annotations.pb.h
-    cpp/google/api/http.pb.cc
-    cpp/google/api/http.pb.h
-    cpp/google/firestore/v1beta1/common.pb.cc
-    cpp/google/firestore/v1beta1/common.pb.h
-    cpp/google/firestore/v1beta1/document.pb.cc
-    cpp/google/firestore/v1beta1/document.pb.h
-    cpp/google/firestore/v1beta1/firestore.pb.cc
-    cpp/google/firestore/v1beta1/firestore.pb.h
-    cpp/google/firestore/v1beta1/query.pb.cc
-    cpp/google/firestore/v1beta1/query.pb.h
-    cpp/google/firestore/v1beta1/write.pb.cc
-    cpp/google/firestore/v1beta1/write.pb.h
-    cpp/google/rpc/status.pb.cc
-    cpp/google/rpc/status.pb.h
-    cpp/google/type/latlng.pb.cc
-    cpp/google/type/latlng.pb.h
+    ${PROTOBUF_CPP_GENERATED_SOURCES}
   DEPENDS
     protobuf::libprotobuf
   EXCLUDE_FROM_ALL
@@ -97,3 +120,141 @@ target_include_directories(
   firebase_firestore_protos_libprotobuf PUBLIC
   ${FIREBASE_SOURCE_DIR}/Firestore/Protos/cpp
 )
+
+
+# Generate the python representation of descriptor.proto.
+set(PROTOBUF_DIR ${FIREBASE_BINARY_DIR}/external/src/grpc/third_party/protobuf)
+set(PROTOBUF_PROTO ${PROTOBUF_DIR}/src/google/protobuf/descriptor.proto)
+set(PROTOBUF_PYTHON ${PROTOBUF_DIR}/python/google/protobuf/descriptor_pb2.py)
+
+add_custom_command(
+  COMMENT "Generating protoc python plugins"
+  OUTPUT ${PROTOBUF_PYTHON}
+  COMMAND
+    protoc
+      -I${PROTOBUF_DIR}/src
+      --python_out=${PROTOBUF_DIR}/python
+      ${PROTOBUF_PROTO}
+  VERBATIM
+  DEPENDS
+    protoc
+    ${PROTOBUF_PROTO}
+)
+
+
+# Generate the python representation of nanopb's protos
+set(NANOPB_DIR ${FIREBASE_BINARY_DIR}/external/src/nanopb)
+set(
+  NANOPB_PROTO
+  ${NANOPB_DIR}/generator/proto/nanopb.proto
+  ${NANOPB_DIR}/generator/proto/plugin.proto
+)
+set(
+  NANOPB_PYTHON
+  ${NANOPB_DIR}/generator/proto/nanopb_pb2.py
+  ${NANOPB_DIR}/generator/proto/plugin_pb2.py
+)
+
+set(
+  PROTO_INCLUDES
+  -I${CMAKE_CURRENT_SOURCE_DIR}/protos
+  -I${NANOPB_DIR}/generator
+  -I${PROTOBUF_DIR}/src
+)
+
+add_custom_command(
+  COMMENT "Generating nanopb python plugins"
+  OUTPUT ${NANOPB_PYTHON}
+  COMMAND
+    protoc
+      -I${NANOPB_DIR}/generator
+      -I${PROTOBUF_DIR}/src
+      --python_out=${NANOPB_DIR}/generator
+      ${NANOPB_PROTO}
+  VERBATIM
+  DEPENDS
+    protoc
+    ${NANOPB_PROTO}
+)
+
+add_custom_command(
+  COMMENT "Generating nanopb sources"
+  OUTPUT ${NANOPB_GENERATED_SOURCES}
+  COMMAND
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+      --nanopb
+      --protoc=$<TARGET_FILE:protoc>
+      --pythonpath=${PROTOBUF_DIR}/python:${NANOPB_DIR}/generator
+      --output_dir=${OUTPUT_DIR}
+      ${PROTO_INCLUDES}
+  VERBATIM
+  DEPENDS
+    protoc
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+    ${CMAKE_CURRENT_SOURCE_DIR}/nanopb_cpp_generator.py
+    ${NANOPB_PYTHON}
+    ${PROTOBUF_PYTHON}
+)
+
+add_custom_target(
+  generate_nanopb_protos
+  DEPENDS
+    ${NANOPB_GENERATED_SOURCES}
+)
+
+add_custom_command(
+  COMMENT "Generating C++ protobuf sources"
+  OUTPUT ${PROTOBUF_CPP_GENERATED_SOURCES}
+  COMMAND
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+      --cpp
+      --protoc=$<TARGET_FILE:protoc>
+      --output_dir=${OUTPUT_DIR}
+      ${PROTO_INCLUDES}
+  VERBATIM
+  DEPENDS
+    protoc
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+)
+
+add_custom_target(
+  generate_cpp_protos
+  DEPENDS
+    ${PROTOBUF_CPP_GENERATED_SOURCES}
+)
+
+add_custom_command(
+  COMMENT "Generating Objective-C protobuf sources"
+  OUTPUT ${PROTOBUF_OBJC_GENERATED_SOURCES}
+  COMMAND
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+      --objc
+      --protoc=$<TARGET_FILE:protoc>
+      --protoc_gen_grpc=$<TARGET_FILE:grpc_objective_c_plugin>
+      --output_dir=${OUTPUT_DIR}
+      ${PROTO_INCLUDES}
+  VERBATIM
+  DEPENDS
+    grpc_objective_c_plugin
+    protoc
+    ${CMAKE_CURRENT_SOURCE_DIR}/build_protos.py
+)
+
+add_custom_target(
+  generate_objc_protos
+  DEPENDS
+    ${PROTOBUF_OBJC_GENERATED_SOURCES}
+)
+
+# Custom target that runs a script to generate the proto sources. This isn't
+# hooked into the build, so must be run manually. (It would be easy enough to
+# hook into the (posix) cmake build, but for consistency with windows and xcode
+# builds, we require this to be run manually with the results checked into
+# source control.)
+add_custom_target(
+  generate_protos
+  DEPENDS
+    generate_nanopb_protos
+    generate_cpp_protos
+    generate_objc_protos
+)

Firestore/Protos/README.md

@@ -17,11 +17,10 @@ make -j protobuf nanopb
 Next, build the protos:
 ```
 cd firebase-ios-sdk/Firestore/Protos
-./build-protos.sh
+./build_protos.py
 ```
 
-Verify diffs (you'll likely need to re-add copyright notices, etc.), make sure
-tests still pass, and create a PR.
+Verify diffs, make sure tests still pass, and create a PR.
 
 ### Script Details