|
| 1 | +// Copyright 2024 Espressif Systems (Shanghai) PTE LTD |
| 2 | +// |
| 3 | +// Licensed under the Apache License, Version 2.0 (the "License"); |
| 4 | +// you may not use this file except in compliance with the License. |
| 5 | +// You may obtain a copy of the License at |
| 6 | + |
| 7 | +// http://www.apache.org/licenses/LICENSE-2.0 |
| 8 | +// |
| 9 | +// Unless required by applicable law or agreed to in writing, software |
| 10 | +// distributed under the License is distributed on an "AS IS" BASIS, |
| 11 | +// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| 12 | +// See the License for the specific language governing permissions and |
| 13 | +// limitations under the License. |
| 14 | + |
| 15 | +// Matter Manager |
| 16 | +#include <Matter.h> |
| 17 | +#include <WiFi.h> |
| 18 | + |
| 19 | +// List of Matter Endpoints for this Node |
| 20 | +// Fan Endpoint - On/Off control + Speed Percent Control + Fan Modes |
| 21 | +MatterFan Fan; |
| 22 | + |
| 23 | +// set your board USER BUTTON pin here - used for toggling On/Off |
| 24 | +const uint8_t buttonPin = 0; // Set your pin here. Using BOOT Button. C6/C3 use GPIO9. |
| 25 | + |
| 26 | +// set your board Analog Pin here - used for changing the Fan speed |
| 27 | +const uint8_t analogPin = A0; // Analog Pin depends on each board |
| 28 | + |
| 29 | +// set your board PWM Pin here - used for controlling the Fan speed (DC motor example) |
| 30 | +// for this example, it will use the builtin board RGB LED to simulate the Fan DC motor using its brightness |
| 31 | +#ifdef RGB_BUILTIN |
| 32 | +const uint8_t dcMotorPin = RGB_BUILTIN; |
| 33 | +#else |
| 34 | +const uint8_t dcMotorPin = 2; // Set your pin here if your board has not defined LED_BUILTIN |
| 35 | +#warning "Do not forget to set the RGB LED pin" |
| 36 | +#endif |
| 37 | + |
| 38 | +// WiFi is manually set and started |
| 39 | +const char *ssid = "your-ssid"; // Change this to your WiFi SSID |
| 40 | +const char *password = "your-password"; // Change this to your WiFi password |
| 41 | + |
| 42 | +void fanDCMotorDrive(bool fanState, uint8_t speedPercent) { |
| 43 | + // drive the Fan DC motor |
| 44 | + if (fanState == false) { |
| 45 | + // turn off the Fan |
| 46 | + digitalWrite(dcMotorPin, LOW); |
| 47 | + } else { |
| 48 | + // set the Fan speed |
| 49 | + uint8_t fanDCMotorPWM = map(speedPercent, 0, 100, 0, 255); |
| 50 | +#ifdef RGB_BUILTIN |
| 51 | + rgbLedWrite(dcMotorPin, fanDCMotorPWM, fanDCMotorPWM, fanDCMotorPWM); |
| 52 | +#else |
| 53 | + analogWrite(dcMotorPin, fanDCMotorPWM); |
| 54 | +#endif |
| 55 | + } |
| 56 | +} |
| 57 | + |
| 58 | +void setup() { |
| 59 | + // Initialize the USER BUTTON (Boot button) GPIO that will toggle the Fan (On/Off) |
| 60 | + pinMode(buttonPin, INPUT_PULLUP); |
| 61 | + // Initialize the Analog Pin A0 used to read input voltage and to set the Fan speed accordingly |
| 62 | + pinMode(analogPin, INPUT); |
| 63 | + analogReadResolution(10); // 10 bits resolution reading 0..1023 |
| 64 | + // Initialize the PWM output pin for a Fan DC motor |
| 65 | + pinMode(dcMotorPin, OUTPUT); |
| 66 | + |
| 67 | + Serial.begin(115200); |
| 68 | + while (!Serial) { |
| 69 | + delay(100); |
| 70 | + } |
| 71 | + |
| 72 | + // We start by connecting to a WiFi network |
| 73 | + Serial.print("Connecting to "); |
| 74 | + Serial.println(ssid); |
| 75 | + // enable IPv6 |
| 76 | + WiFi.enableIPv6(true); |
| 77 | + // Manually connect to WiFi |
| 78 | + WiFi.begin(ssid, password); |
| 79 | + // Wait for connection |
| 80 | + while (WiFi.status() != WL_CONNECTED) { |
| 81 | + delay(500); |
| 82 | + Serial.print("."); |
| 83 | + } |
| 84 | + Serial.println("\r\nWiFi connected"); |
| 85 | + Serial.println("IP address: "); |
| 86 | + Serial.println(WiFi.localIP()); |
| 87 | + delay(500); |
| 88 | + |
| 89 | + // On Boot or Reset, Fan is set at 0% speed, OFF, changing between OFF, ON, SMART and HIGH |
| 90 | + Fan.begin(0, MatterFan::FAN_MODE_OFF, MatterFan::FAN_MODE_SEQ_OFF_HIGH); |
| 91 | + |
| 92 | + // callback functions would control Fan motor |
| 93 | + // the Matter Controller will send new data whenever the User APP or Automation request |
| 94 | + |
| 95 | + // single feature callbacks take place before the generic (all features) callback |
| 96 | + // This callback will be executed whenever the speed percent matter attribute is updated |
| 97 | + Fan.onChangeSpeedPercent([](uint8_t speedPercent) { |
| 98 | + // setting speed to Zero, while the Fan is ON, shall turn the Fan OFF |
| 99 | + if (speedPercent == MatterFan::OFF_SPEED && Fan.getMode() != MatterFan::FAN_MODE_OFF) { |
| 100 | + // ATTR_SET do not update the attribute, just SET it to avoid infinite loop |
| 101 | + return Fan.setOnOff(false, Fan.ATTR_SET); |
| 102 | + } |
| 103 | + // changing the speed to higher than Zero, while the Fan is OFF, shall turn the Fan ON |
| 104 | + if (speedPercent > MatterFan::OFF_SPEED && Fan.getMode() == MatterFan::FAN_MODE_OFF) { |
| 105 | + // ATTR_SET do not update the attribute, just SET it to avoid infinite loop |
| 106 | + return Fan.setOnOff(true, Fan.ATTR_SET); |
| 107 | + } |
| 108 | + // for other case, just return true |
| 109 | + return true; |
| 110 | + }); |
| 111 | + |
| 112 | + // This callback will be executed whenever the fan mode matter attribute is updated |
| 113 | + // This will take action when user APP starts the Fan by changing the mode |
| 114 | + Fan.onChangeMode([](MatterFan::FanMode_t fanMode) { |
| 115 | + // when the Fan is turned ON using Mode Selection, while it is OFF, shall start it by setting the speed to 50% |
| 116 | + if (Fan.getSpeedPercent() == MatterFan::OFF_SPEED && fanMode != MatterFan::FAN_MODE_OFF) { |
| 117 | + Serial.printf("Fan set to %s mode -- speed percentage will go to 50%%\r\n", Fan.getFanModeString(fanMode)); |
| 118 | + // ATTR_SET do not update the attribute, just SET it to avoid infinite loop |
| 119 | + return Fan.setSpeedPercent(50, Fan.ATTR_SET); |
| 120 | + } |
| 121 | + return true; |
| 122 | + }); |
| 123 | + |
| 124 | + // Generic callback will be executed as soon as a single feature callback is done |
| 125 | + // In this example, it will just print status messages |
| 126 | + Fan.onChange([](MatterFan::FanMode_t fanMode, uint8_t speedPercent) { |
| 127 | + // just report state |
| 128 | + Serial.printf("Fan State: Mode %s | %d%% speed.\r\n", Fan.getFanModeString(fanMode), speedPercent); |
| 129 | + // drive the Fan DC motor |
| 130 | + fanDCMotorDrive(fanMode != MatterFan::FAN_MODE_OFF, speedPercent); |
| 131 | + // returns success |
| 132 | + return true; |
| 133 | + }); |
| 134 | + |
| 135 | + // Matter beginning - Last step, after all EndPoints are initialized |
| 136 | + Matter.begin(); |
| 137 | + // This may be a restart of a already commissioned Matter accessory |
| 138 | + if (Matter.isDeviceCommissioned()) { |
| 139 | + Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use."); |
| 140 | + } |
| 141 | +} |
| 142 | + |
| 143 | +// Builtin Button control |
| 144 | +uint32_t button_time_stamp = 0; // debouncing control |
| 145 | +bool button_state = false; // false = released | true = pressed |
| 146 | +const uint32_t debouceTime = 250; // button debouncing time (ms) |
| 147 | +const uint32_t decommissioningTimeout = 10000; // keep the button pressed for 10s to decommission the Matter Fabric |
| 148 | + |
| 149 | +void loop() { |
| 150 | + // Check Matter Accessory Commissioning state, which may change during execution of loop() |
| 151 | + if (!Matter.isDeviceCommissioned()) { |
| 152 | + Serial.println(""); |
| 153 | + Serial.println("Matter Node is not commissioned yet."); |
| 154 | + Serial.println("Initiate the device discovery in your Matter environment."); |
| 155 | + Serial.println("Commission it to your Matter hub with the manual pairing code or QR code"); |
| 156 | + Serial.printf("Manual pairing code: %s\r\n", Matter.getManualPairingCode().c_str()); |
| 157 | + Serial.printf("QR code URL: %s\r\n", Matter.getOnboardingQRCodeUrl().c_str()); |
| 158 | + // waits for Matter Generic Switch Commissioning. |
| 159 | + uint32_t timeCount = 0; |
| 160 | + while (!Matter.isDeviceCommissioned()) { |
| 161 | + delay(100); |
| 162 | + if ((timeCount++ % 50) == 0) { // 50*100ms = 5 sec |
| 163 | + Serial.println("Matter Node not commissioned yet. Waiting for commissioning."); |
| 164 | + } |
| 165 | + } |
| 166 | + Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use."); |
| 167 | + } |
| 168 | + |
| 169 | + // A builtin button is used to trigger and send a command to the Matter Controller |
| 170 | + // Check if the button has been pressed |
| 171 | + if (digitalRead(buttonPin) == LOW && !button_state) { |
| 172 | + // deals with button debouncing |
| 173 | + button_time_stamp = millis(); // record the time while the button is pressed. |
| 174 | + button_state = true; // pressed. |
| 175 | + } |
| 176 | + |
| 177 | + // Onboard User Button is used as a smart button or to decommission it |
| 178 | + uint32_t time_diff = millis() - button_time_stamp; |
| 179 | + if (button_state && time_diff > debouceTime && digitalRead(buttonPin) == HIGH) { |
| 180 | + button_state = false; // released |
| 181 | + // button is released - toggle Fan On/Off |
| 182 | + Fan.toggle(); |
| 183 | + Serial.printf("User button released. Setting the Fan %s.\r\n", Fan > 0 ? "ON" : "OFF"); |
| 184 | + |
| 185 | + // Factory reset is triggered if the button is pressed longer than 10 seconds |
| 186 | + if (time_diff > decommissioningTimeout) { |
| 187 | + Serial.println("Decommissioning the Generic Switch Matter Accessory. It shall be commissioned again."); |
| 188 | + Matter.decommission(); |
| 189 | + } |
| 190 | + } |
| 191 | + |
| 192 | + // checks Analog pin and adjust the speed only if it has changed |
| 193 | + static int lastRead = 0; |
| 194 | + // analog values (0..1023) / 103 => mapped into 10 steps (0..9) |
| 195 | + int anaVal = analogRead(analogPin) / 103; |
| 196 | + if (lastRead != anaVal) { |
| 197 | + // speed percent moves in steps of 10. Range is 10..100 |
| 198 | + if (Fan.setSpeedPercent((anaVal + 1) * 10)) { |
| 199 | + lastRead = anaVal; |
| 200 | + } |
| 201 | + } |
| 202 | +} |
0 commit comments