|
| 1 | +// Copyright 2024 Espressif Systems (Shanghai) PTE LTD |
| 2 | +// |
| 3 | +// Licensed under the Apache License, Version 2.0 (the "License"); |
| 4 | +// you may not use this file except in compliance with the License. |
| 5 | +// You may obtain a copy of the License at |
| 6 | + |
| 7 | +// http://www.apache.org/licenses/LICENSE-2.0 |
| 8 | +// |
| 9 | +// Unless required by applicable law or agreed to in writing, software |
| 10 | +// distributed under the License is distributed on an "AS IS" BASIS, |
| 11 | +// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| 12 | +// See the License for the specific language governing permissions and |
| 13 | +// limitations under the License. |
| 14 | + |
| 15 | +// Matter Manager |
| 16 | +#include <Matter.h> |
| 17 | +#include <WiFi.h> |
| 18 | +#include <Preferences.h> |
| 19 | + |
| 20 | +// List of Matter Endpoints for this Node |
| 21 | +// Dimmable Light Endpoint |
| 22 | +MatterDimmableLight DimmableLight; |
| 23 | + |
| 24 | +// it will keep last OnOff & Brightness state stored, using Preferences |
| 25 | +Preferences lastStatePref; |
| 26 | + |
| 27 | +// set your board RGB LED pin here |
| 28 | +#ifdef RGB_BUILTIN |
| 29 | +const uint8_t ledPin = RGB_BUILTIN; |
| 30 | +#else |
| 31 | +const uint8_t ledPin = 2; // Set your pin here if your board has not defined LED_BUILTIN |
| 32 | +#warning "Do not forget to set the RGB LED pin" |
| 33 | +#endif |
| 34 | + |
| 35 | +// set your board USER BUTTON pin here |
| 36 | +const uint8_t buttonPin = 0; // Set your pin here. Using BOOT Button. C6/C3 use GPIO9. |
| 37 | + |
| 38 | +// WiFi is manually set and started |
| 39 | +const char *ssid = "your-ssid"; // Change this to your WiFi SSID |
| 40 | +const char *password = "your-password"; // Change this to your WiFi password |
| 41 | + |
| 42 | +// Set the RGB LED Light based on the current state of the Dimmable Light |
| 43 | +bool setLightState(bool state, uint8_t brightness) { |
| 44 | + if (state) { |
| 45 | +#ifdef RGB_BUILTIN |
| 46 | + rgbLedWrite(ledPin, brightness, brightness, brightness); |
| 47 | +#else |
| 48 | + analogWrite(ledPin, brightness); |
| 49 | +#endif |
| 50 | + } else { |
| 51 | + digitalWrite(ledPin, LOW); |
| 52 | + } |
| 53 | + // store last Brightness and OnOff state for when the Light is restarted / power goes off |
| 54 | + lastStatePref.putUChar("lastBrightness", brightness); |
| 55 | + lastStatePref.putBool("lastOnOffState", state); |
| 56 | + // This callback must return the success state to Matter core |
| 57 | + return true; |
| 58 | +} |
| 59 | + |
| 60 | +void setup() { |
| 61 | + // Initialize the USER BUTTON (Boot button) GPIO that will act as a toggle switch |
| 62 | + pinMode(buttonPin, INPUT_PULLUP); |
| 63 | + // Initialize the LED (light) GPIO and Matter End Point |
| 64 | + pinMode(ledPin, OUTPUT); |
| 65 | + |
| 66 | + Serial.begin(115200); |
| 67 | + while (!Serial) { |
| 68 | + delay(100); |
| 69 | + } |
| 70 | + |
| 71 | + // We start by connecting to a WiFi network |
| 72 | + Serial.print("Connecting to "); |
| 73 | + Serial.println(ssid); |
| 74 | + // enable IPv6 |
| 75 | + WiFi.enableIPv6(true); |
| 76 | + // Manually connect to WiFi |
| 77 | + WiFi.begin(ssid, password); |
| 78 | + // Wait for connection |
| 79 | + while (WiFi.status() != WL_CONNECTED) { |
| 80 | + delay(500); |
| 81 | + Serial.print("."); |
| 82 | + } |
| 83 | + Serial.println("\r\nWiFi connected"); |
| 84 | + Serial.println("IP address: "); |
| 85 | + Serial.println(WiFi.localIP()); |
| 86 | + delay(500); |
| 87 | + |
| 88 | + // Initialize Matter EndPoint |
| 89 | + lastStatePref.begin("matterLight", false); |
| 90 | + // default OnOff state is ON if not stored before |
| 91 | + bool lastOnOffState = lastStatePref.getBool("lastOnOffState", true); |
| 92 | + // default brightness ~= 6% (15/255) |
| 93 | + uint8_t lastBrightness = lastStatePref.getUChar("lastBrightness", 15); |
| 94 | + DimmableLight.begin(lastOnOffState, lastBrightness); |
| 95 | + // set the callback function to handle the Light state change |
| 96 | + DimmableLight.onChange(setLightState); |
| 97 | + |
| 98 | + // lambda functions are used to set the attribute change callbacks |
| 99 | + DimmableLight.onChangeOnOff([](bool state) { |
| 100 | + Serial.printf("Light OnOff changed to %s\r\n", state ? "ON" : "OFF"); |
| 101 | + return true; |
| 102 | + }); |
| 103 | + DimmableLight.onChangeBrightness([](uint8_t level) { |
| 104 | + Serial.printf("Light Brightness changed to %d\r\n", level); |
| 105 | + return true; |
| 106 | + }); |
| 107 | + |
| 108 | + // Matter beginning - Last step, after all EndPoints are initialized |
| 109 | + Matter.begin(); |
| 110 | + // This may be a restart of a already commissioned Matter accessory |
| 111 | + if (Matter.isDeviceCommissioned()) { |
| 112 | + Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use."); |
| 113 | + Serial.printf("Initial state: %s | brightness: %d\r\n", DimmableLight ? "ON" : "OFF", DimmableLight.getBrightness()); |
| 114 | + // configure the Light based on initial on-off state and brightness |
| 115 | + DimmableLight.updateAccessory(); |
| 116 | + } |
| 117 | +} |
| 118 | +// Button control |
| 119 | +uint32_t button_time_stamp = 0; // debouncing control |
| 120 | +bool button_state = false; // false = released | true = pressed |
| 121 | +const uint32_t debouceTime = 250; // button debouncing time (ms) |
| 122 | +const uint32_t decommissioningTimeout = 10000; // keep the button pressed for 10s to decommission the light |
| 123 | + |
| 124 | +void loop() { |
| 125 | + // Check Matter Light Commissioning state, which may change during execution of loop() |
| 126 | + if (!Matter.isDeviceCommissioned()) { |
| 127 | + Serial.println(""); |
| 128 | + Serial.println("Matter Node is not commissioned yet."); |
| 129 | + Serial.println("Initiate the device discovery in your Matter environment."); |
| 130 | + Serial.println("Commission it to your Matter hub with the manual pairing code or QR code"); |
| 131 | + Serial.printf("Manual pairing code: %s\r\n", Matter.getManualPairingCode().c_str()); |
| 132 | + Serial.printf("QR code URL: %s\r\n", Matter.getOnboardingQRCodeUrl().c_str()); |
| 133 | + // waits for Matter Light Commissioning. |
| 134 | + uint32_t timeCount = 0; |
| 135 | + while (!Matter.isDeviceCommissioned()) { |
| 136 | + delay(100); |
| 137 | + if ((timeCount++ % 50) == 0) { // 50*100ms = 5 sec |
| 138 | + Serial.println("Matter Node not commissioned yet. Waiting for commissioning."); |
| 139 | + } |
| 140 | + } |
| 141 | + Serial.printf("Initial state: %s | brightness: %d\r\n", DimmableLight ? "ON" : "OFF", DimmableLight.getBrightness()); |
| 142 | + // configure the Light based on initial on-off state and brightness |
| 143 | + DimmableLight.updateAccessory(); |
| 144 | + Serial.println("Matter Node is commissioned and connected to Wi-Fi. Ready for use."); |
| 145 | + } |
| 146 | + |
| 147 | + // A button is also used to control the light |
| 148 | + // Check if the button has been pressed |
| 149 | + if (digitalRead(buttonPin) == LOW && !button_state) { |
| 150 | + // deals with button debouncing |
| 151 | + button_time_stamp = millis(); // record the time while the button is pressed. |
| 152 | + button_state = true; // pressed. |
| 153 | + } |
| 154 | + |
| 155 | + // Onboard User Button is used as a Light toggle switch or to decommission it |
| 156 | + uint32_t time_diff = millis() - button_time_stamp; |
| 157 | + if (button_state && time_diff > debouceTime && digitalRead(buttonPin) == HIGH) { |
| 158 | + button_state = false; // released |
| 159 | + // Toggle button is released - toggle the light |
| 160 | + Serial.println("User button released. Toggling Light!"); |
| 161 | + DimmableLight.toggle(); // Matter Controller also can see the change |
| 162 | + |
| 163 | + // Factory reset is triggered if the button is pressed longer than 10 seconds |
| 164 | + if (time_diff > decommissioningTimeout) { |
| 165 | + Serial.println("Decommissioning the Light Matter Accessory. It shall be commissioned again."); |
| 166 | + DimmableLight = false; // turn the light off |
| 167 | + Matter.decommission(); |
| 168 | + } |
| 169 | + } |
| 170 | +} |
![pre-commit-ci-lite[bot]](https://avatars.githubusercontent.com/in/257897?v=4&size=40){kind=avatar}
0 commit comments