diff --git a/lib/elixir/lib/io/ansi/docs.ex b/lib/elixir/lib/io/ansi/docs.ex
index 0f1af54cf65..cda3bdd9f2b 100644
--- a/lib/elixir/lib/io/ansi/docs.ex
+++ b/lib/elixir/lib/io/ansi/docs.ex
@@ -118,10 +118,196 @@ defmodule IO.ANSI.Docs do
     print_markdown(doc, options)
   end
 
+  def print(doc, "application/erlang+html", options) when is_list(options) do
+    print_erlang_html(doc, options)
+  end
+
   def print(_doc, format, options) when is_binary(format) and is_list(options) do
     IO.puts("\nUnknown documentation format #{inspect(format)}\n")
   end
 
+  ## Erlang+html
+
+  def print_erlang_html(doc, options) do
+    options = Keyword.merge(default_options(), options)
+    IO.write(traverse_erlang_html(doc, "", options))
+  end
+
+  defp traverse_erlang_html(text, _indent, _options) when is_binary(text) do
+    text
+  end
+
+  defp traverse_erlang_html(nodes, indent, options) when is_list(nodes) do
+    for node <- nodes do
+      traverse_erlang_html(node, indent, options)
+    end
+  end
+
+  defp traverse_erlang_html({:div, [class: class] ++ _, entries}, indent, options) do
+    prefix = indent <> quote_prefix(options)
+
+    content =
+      entries
+      |> traverse_erlang_html(indent, options)
+      |> IO.iodata_to_binary()
+      |> String.trim_trailing()
+
+    [
+      prefix,
+      class |> to_string() |> String.upcase(),
+      "\n#{prefix}\n#{prefix}" | String.replace(content, "\n", "\n#{prefix}")
+    ]
+    |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:p, _, entries}, indent, options) do
+    [indent | handle_erlang_html_text(entries, indent, options)]
+  end
+
+  defp traverse_erlang_html({:h1, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(1, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:h2, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(2, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:h3, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(3, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:h4, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(4, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:h5, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(5, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:h6, _, entries}, indent, options) do
+    entries |> traverse_erlang_html(indent, options) |> heading(6, options) |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:br, _, []}, _indent, _options) do
+    []
+  end
+
+  defp traverse_erlang_html({:i, _, entries}, indent, options) do
+    inline_text("_", traverse_erlang_html(entries, indent, options), options)
+  end
+
+  defp traverse_erlang_html({:em, _, entries}, indent, options) do
+    inline_text("*", traverse_erlang_html(entries, indent, options), options)
+  end
+
+  defp traverse_erlang_html({tag, _, entries}, indent, options) when tag in [:strong, :b] do
+    inline_text("**", traverse_erlang_html(entries, indent, options), options)
+  end
+
+  defp traverse_erlang_html({:code, _, entries}, indent, options) do
+    inline_text("`", traverse_erlang_html(entries, indent, options), options)
+  end
+
+  defp traverse_erlang_html({:pre, _, [{:code, _, entries}]}, indent, options) do
+    string =
+      entries
+      |> traverse_erlang_html(indent, options)
+      |> IO.iodata_to_binary()
+
+    ["#{indent}    ", String.replace(string, "\n", "\n#{indent}    ")] |> newline_cons()
+  end
+
+  defp traverse_erlang_html({:a, attributes, entries}, indent, options) do
+    if href = attributes[:href] do
+      [traverse_erlang_html(entries, indent, options), ?\s, ?(, href, ?)]
+    else
+      traverse_erlang_html(entries, indent, options)
+    end
+  end
+
+  defp traverse_erlang_html({:dl, _, entries}, indent, options) do
+    traverse_erlang_html(entries, indent, options)
+  end
+
+  defp traverse_erlang_html({:dt, _, entries}, indent, options) do
+    [
+      "#{indent}  ",
+      bullet_text(options) | handle_erlang_html_text(entries, indent <> "    ", options)
+    ]
+  end
+
+  defp traverse_erlang_html({:dd, _, entries}, indent, options) do
+    ["#{indent}    " | handle_erlang_html_text(entries, indent <> "    ", options)]
+  end
+
+  defp traverse_erlang_html({:ul, attributes, entries}, indent, options) do
+    if attributes[:class] == "types" do
+      types =
+        for {:li, _, lines} <- entries,
+            line <- lines,
+            do: ["#{indent}    ", traverse_erlang_html(line, indent <> "    ", options), ?\n]
+
+      if types != [] do
+        ["#{indent}Typespecs:\n\n", types, ?\n]
+      else
+        []
+      end
+    else
+      for {:li, _, lines} <- entries do
+        [
+          "#{indent}  ",
+          bullet_text(options) | handle_erlang_html_text(lines, indent <> "    ", options)
+        ]
+      end
+    end
+  end
+
+  defp traverse_erlang_html({:ol, _, entries}, indent, options) do
+    for {{:li, _, lines}, i} <- Enum.with_index(entries, 1) do
+      [
+        "#{indent}  ",
+        Integer.to_string(i),
+        ". " | handle_erlang_html_text(lines, indent <> "     ", options)
+      ]
+    end
+  end
+
+  defp traverse_erlang_html({tag, _, entries}, indent, options) do
+    [
+      indent <> "<#{tag}>\n",
+      traverse_erlang_html(entries, indent <> "    ", options)
+      |> IO.iodata_to_binary()
+      |> String.trim_trailing(),
+      "\n" <> indent <> "</#{tag}>"
+    ]
+    |> newline_cons()
+  end
+
+  defp newline_cons(text) do
+    [text | "\n\n"]
+  end
+
+  defp handle_erlang_html_text(entries, indent, options) do
+    if Enum.all?(entries, &inline_html?/1) do
+      entries
+      |> traverse_erlang_html(indent, options)
+      |> IO.iodata_to_binary()
+      |> String.split(@spaces)
+      |> wrap_text(options[:width], indent, true, "", [])
+      |> tl()
+      |> newline_cons()
+    else
+      entries
+      |> traverse_erlang_html(indent, options)
+      |> IO.iodata_to_binary()
+      |> String.trim_leading()
+    end
+  end
+
+  defp inline_html?(binary) when is_binary(binary), do: true
+  defp inline_html?({tag, _, _}) when tag in [:a, :code, :em, :i, :strong, :b, :br], do: true
+  defp inline_html?(_), do: false
+
   ## Markdown
 
   def print_markdown(doc, options) do
@@ -176,19 +362,14 @@ defmodule IO.ANSI.Docs do
     process_code(rest, [line], indent, options)
   end
 
-  defp process(["```mermaid" <> _line | rest], text, indent, options) do
-    write_text(text, indent, options)
-
-    rest
-    |> Enum.drop_while(&(&1 != "```"))
-    |> Enum.drop(1)
-    |> process([], indent, options)
-  end
-
   defp process(["```" <> _line | rest], text, indent, options) do
     process_fenced_code_block(rest, text, indent, options, _delimiter = "```")
   end
 
+  defp process(["~~~" <> _line | rest], text, indent, options) do
+    process_fenced_code_block(rest, text, indent, options, _delimiter = "~~~")
+  end
+
   defp process(["<!--" <> line | rest], text, indent, options) do
     process(drop_comment([line | rest]), text, indent, options)
   end
@@ -221,6 +402,10 @@ defmodule IO.ANSI.Docs do
 
   ### Quotes
 
+  defp process_quote([], lines, indent, options) do
+    write_quote(lines, indent, options, false)
+  end
+
   defp process_quote([">", ">" <> line | rest], lines, indent, options) do
     write_quote(lines, indent, options, true)
     write_empty_quote_line(options)
@@ -361,6 +546,10 @@ defmodule IO.ANSI.Docs do
 
   ### Code blocks
 
+  defp process_code([], code, indent, options) do
+    write_code(code, indent, options)
+  end
+
   # Blank line between code blocks
   defp process_code(["", "    " <> line | rest], code, indent, options) do
     process_code(rest, [line, "" | code], indent, options)
@@ -385,7 +574,7 @@ defmodule IO.ANSI.Docs do
   end
 
   defp process_fenced_code([line | rest], code, indent, options, delimiter) do
-    if line == delimiter do
+    if line === delimiter do
       process_code(rest, code, indent, options)
     else
       process_fenced_code(rest, [line | code], indent, options, delimiter)
@@ -764,6 +953,10 @@ defmodule IO.ANSI.Docs do
 
   defp quote_prefix(options), do: "#{color(:doc_quote, options)}> #{maybe_reset(options)}"
 
+  defp heading(text, n, options) do
+    [color(:doc_headings, options), String.duplicate("#", n), " ", text, maybe_reset(options)]
+  end
+
   defp inline_text(mark, text, options) do
     if options[:enabled] do
       [[color_for(mark, options) | text] | IO.ANSI.reset()]
diff --git a/lib/elixir/test/elixir/io/ansi/docs_test.exs b/lib/elixir/test/elixir/io/ansi/docs_test.exs
index db7828381bb..b46b6350b58 100644
--- a/lib/elixir/test/elixir/io/ansi/docs_test.exs
+++ b/lib/elixir/test/elixir/io/ansi/docs_test.exs
@@ -17,6 +17,10 @@ defmodule IO.ANSI.DocsTest do
     |> String.trim_trailing()
   end
 
+  def format_erlang(str, opts \\ []) do
+    capture_io(fn -> IO.ANSI.Docs.print(str, "application/erlang+html", opts) end)
+  end
+
   describe "heading" do
     test "is formatted" do
       result = format_headings(["foo"])
@@ -187,11 +191,8 @@ defmodule IO.ANSI.DocsTest do
       assert result == "line\n\e[0m\n\e[36m    code\n    code2\e[0m\n\e[0m\nline2\n\e[0m"
       result = format_markdown("line\n```elixir\ncode\ncode2\n```\nline2\n")
       assert result == "line\n\e[0m\n\e[36m    code\n    code2\e[0m\n\e[0m\nline2\n\e[0m"
-    end
-
-    test "mermaid fenced code block is discarded" do
-      result = format_markdown("line\n```mermaid\ncode\ncode2\n```\nline2\n")
-      assert result == "line\n\e[0m\nline2\n\e[0m"
+      result = format_markdown("line\n~~~elixir\ncode\n```\n~~~\nline2\n")
+      assert result == "line\n\e[0m\n\e[36m    code\n    ```\e[0m\n\e[0m\nline2\n\e[0m"
     end
 
     test "* list is converted" do
@@ -655,6 +656,205 @@ defmodule IO.ANSI.DocsTest do
     end
   end
 
+  describe "erlang" do
+    @hello_world [{:p, [], ["Hello"]}, {:p, [], ["World"]}]
+
+    test "text" do
+      assert format_erlang("Hello world") == "Hello world"
+    end
+
+    test "skips line breaks" do
+      assert format_erlang([{:p, [], ["Hello"]}, {:br, [], []}, {:p, [], ["World"]}]) ==
+               "Hello\n\nWorld\n\n"
+    end
+
+    test "paragraphs" do
+      assert format_erlang(@hello_world) == "Hello\n\nWorld\n\n"
+    end
+
+    test "code chunks" do
+      code = """
+      def foo do
+        :bar
+      end\
+      """
+
+      assert format_erlang({:pre, [], [{:code, [], [code]}]}) == """
+                 def foo do
+                   :bar
+                 end
+
+             """
+    end
+
+    test "unordered lists" do
+      assert format_erlang([{:ul, [], [{:li, [], ["Hello"]}, {:li, [], ["World"]}]}]) ==
+               "  • Hello\n\n  • World\n\n"
+
+      assert format_erlang([{:ul, [], [{:li, [], [@hello_world]}]}]) ==
+               "  • Hello\n\n    World\n\n"
+
+      assert format_erlang([
+               {:ul, [], [{:li, [], [{:p, [], ["Hello"]}]}, {:li, [], [{:p, [], ["World"]}]}]}
+             ]) ==
+               "  • Hello\n\n  • World\n\n"
+    end
+
+    test "ordered lists" do
+      assert format_erlang([{:ol, [], [{:li, [], ["Hello"]}, {:li, [], ["World"]}]}]) ==
+               "  1. Hello\n\n  2. World\n\n"
+
+      assert format_erlang([
+               {:ol, [], [{:li, [], [{:p, [], ["Hello"]}]}, {:li, [], [{:p, [], ["World"]}]}]}
+             ]) ==
+               "  1. Hello\n\n  2. World\n\n"
+    end
+
+    test "admonition blocks" do
+      assert format_erlang([{:div, [class: "warning"], @hello_world}]) == """
+             \e[90m> \e[0mWARNING
+             \e[90m> \e[0m
+             \e[90m> \e[0mHello
+             \e[90m> \e[0m
+             \e[90m> \e[0mWorld
+
+             """
+    end
+
+    test "headers" do
+      assert format_erlang([{:h1, [], ["Hello"]}]) ==
+               "\e[33m# Hello\e[0m\n\n"
+
+      assert format_erlang([{:h2, [], ["Hello"]}]) ==
+               "\e[33m## Hello\e[0m\n\n"
+
+      assert format_erlang([{:h3, [], ["Hello"]}]) ==
+               "\e[33m### Hello\e[0m\n\n"
+
+      assert format_erlang([{:h4, [], ["Hello"]}]) ==
+               "\e[33m#### Hello\e[0m\n\n"
+
+      assert format_erlang([{:h5, [], ["Hello"]}]) ==
+               "\e[33m##### Hello\e[0m\n\n"
+
+      assert format_erlang([{:h6, [], ["Hello"]}]) ==
+               "\e[33m###### Hello\e[0m\n\n"
+
+      assert format_erlang([{:h1, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m# \e[36mHello\e[0m\e[0m\n\n"
+
+      assert format_erlang([{:h2, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m## \e[36mHello\e[0m\e[0m\n\n"
+
+      assert format_erlang([{:h3, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m### \e[36mHello\e[0m\e[0m\n\n"
+
+      assert format_erlang([{:h4, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m#### \e[36mHello\e[0m\e[0m\n\n"
+
+      assert format_erlang([{:h5, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m##### \e[36mHello\e[0m\e[0m\n\n"
+
+      assert format_erlang([{:h6, [], [{:code, [], ["Hello"]}]}]) ==
+               "\e[33m###### \e[36mHello\e[0m\e[0m\n\n"
+    end
+
+    test "inline tags" do
+      assert format_erlang([{:i, [], ["Hello"]}]) == "\e[4mHello\e[0m"
+      assert format_erlang([{:i, [], ["Hello"]}], enabled: false) == "_Hello_"
+
+      assert format_erlang([{:em, [], ["Hello"]}]) == "\e[4mHello\e[0m"
+      assert format_erlang([{:em, [], ["Hello"]}], enabled: false) == "*Hello*"
+
+      assert format_erlang([{:b, [], ["Hello"]}]) == "\e[1mHello\e[0m"
+      assert format_erlang([{:b, [], ["Hello"]}], enabled: false) == "**Hello**"
+      assert format_erlang([{:strong, [], ["Hello"]}]) == "\e[1mHello\e[0m"
+      assert format_erlang([{:strong, [], ["Hello"]}], enabled: false) == "**Hello**"
+
+      assert format_erlang([{:code, [], ["Hello"]}]) == "\e[36mHello\e[0m"
+      assert format_erlang([{:code, [], ["Hello"]}], enabled: false) == "`Hello`"
+    end
+
+    test "inline tags within paragraphs" do
+      assert format_erlang([{:p, [], [[{:em, [], ["Hello"]}, {:code, [], ["World"]}]]}]) ==
+               "\e[4mHello\e[0m\e[36mWorld\e[0m"
+    end
+
+    test "inline tags within list item" do
+      assert format_erlang([
+               {:ul, [], [{:li, [], [{:em, [], ["Hello"]}, {:code, [], ["World"]}]}]}
+             ]) ==
+               "  • \e[4mHello\e[0m\e[36mWorld\e[0m\n\n"
+    end
+
+    test "links" do
+      assert format_erlang([{:a, [], ["Hello"]}]) == "Hello"
+      assert format_erlang([{:a, [href: "foo/bar"], ["Hello"]}]) == "Hello (foo/bar)"
+    end
+
+    test "definition lists" do
+      assert format_erlang([{:dl, [], [[{:dt, [], ["Hello"]}, {:dd, [], ["World"]}]]}]) == """
+               • Hello
+
+                 World
+
+             """
+    end
+
+    test "typespecs" do
+      assert format_erlang([{:ul, [class: "types"], [{:li, [], []}]}]) == ""
+
+      assert format_erlang([{:ul, [class: "types"], [{:li, [], ["Hello"]}, {:li, [], ["World"]}]}]) ==
+               """
+               Typespecs:
+
+                   Hello
+                   World
+
+               """
+
+      assert format_erlang([
+               {:ul, [class: "types"], [{:li, [], ["Hello", {:code, [], ["World"]}]}]}
+             ]) ==
+               """
+               Typespecs:
+
+                   Hello
+                   \e[36mWorld\e[0m
+
+               """
+    end
+
+    test "extra markup" do
+      assert format_erlang([{:p, [], ["Hello"]}, {:unknown, [], ["Unknown"]}, {:p, [], ["World"]}]) ==
+               """
+               Hello
+
+               <unknown>
+               Unknown
+               </unknown>
+
+               World
+
+               """
+
+      assert format_erlang([
+               {:p, [], ["Hello"]},
+               {:unknown, [], [{:p, [], ["Unknown"]}]},
+               {:p, [], ["World"]}
+             ]) == """
+             Hello
+
+             <unknown>
+                 Unknown
+             </unknown>
+
+             World
+
+             """
+    end
+  end
+
   describe "invalid format" do
     test "prints message" do
       assert capture_io(fn -> IO.ANSI.Docs.print("hello", "text/unknown", []) end) ==
diff --git a/lib/iex/lib/iex/introspection.ex b/lib/iex/lib/iex/introspection.ex
index a0ee301e9d6..e0f1c3ba41a 100644
--- a/lib/iex/lib/iex/introspection.ex
+++ b/lib/iex/lib/iex/introspection.ex
@@ -258,19 +258,7 @@ defmodule IEx.Introspection do
   def h(module) when is_atom(module) do
     case Code.ensure_loaded(module) do
       {:module, _} ->
-        case Code.fetch_docs(module) do
-          {:docs_v1, _, :erlang, _, _, _, _} = erl_docs ->
-            :shell_docs.render(module, erl_docs) |> IO.puts()
-
-          {:docs_v1, _, _, format, %{} = doc, metadata, _} ->
-            print_doc([inspect(module)], [], format, doc, metadata)
-
-          {:docs_v1, _, _, _, _, _, _} ->
-            docs_not_found(inspect(module))
-
-          _ ->
-            no_docs(module)
-        end
+        :shell_docs.get_doc(module) |> IO.ANSI.Docs.print_erlang_html(IEx.Config.ansi_docs())
 
       {:error, reason} ->
         puts_error("Could not load module #{inspect(module)}, got: #{reason}")