Type Tuple.delete_at/2

Author: josevalim

lib/elixir/lib/module/types/of.ex

@@ -326,6 +326,24 @@ defmodule Module.Types.Of do
     end
   end
 
+  def apply(
+        :erlang,
+        :delete_element,
+        [_, tuple],
+        {_, meta, [index, _]} = expr,
+        stack,
+        context
+      )
+      when is_integer(index) do
+    case tuple_delete_at(tuple, index - 1) do
+      value_type when is_descr(value_type) ->
+        {value_type, context}
+
+      reason ->
+        {error_type(), error({reason, expr, tuple, index - 1, context}, meta, stack, context)}
+    end
+  end
+
   def apply(:erlang, name, [left, right], expr, stack, context)
       when name in [:>=, :"=<", :>, :<, :min, :max] do
     result = if name in [:min, :max], do: union(left, right), else: boolean()

lib/elixir/test/elixir/module/types/expr_test.exs

@@ -327,6 +327,43 @@ defmodule Module.Types.ExprTest do
                     {:ok, integer()}
                 """}
     end
+
+    test "Tuple.delete_at/2" do
+      assert typecheck!(Tuple.delete_at({:ok, 123}, 0)) == tuple([integer()])
+      assert typecheck!(Tuple.delete_at({:ok, 123}, 1)) == tuple([atom([:ok])])
+      assert typecheck!([x], Tuple.delete_at({:ok, x}, 0)) == dynamic(tuple([term()]))
+      assert typecheck!([x], Tuple.delete_at({:ok, x}, 1)) == dynamic(tuple([atom([:ok])]))
+
+      assert typewarn!([<<x::integer>>], Tuple.delete_at(x, 0)) ==
+               {dynamic(),
+                ~l"""
+                expected a tuple in expression:
+
+                    Tuple.delete_at(x, 0)
+
+                but got type:
+
+                    integer()
+
+                where "x" was given the type:
+
+                    # type: integer()
+                    # from: types_test.ex:LINE-2
+                    <<x::integer>>
+                """}
+
+      assert typewarn!(Tuple.delete_at({:ok, 123}, 2)) ==
+               {dynamic(),
+                ~l"""
+                expected a tuple with at least 3 elements in expression:
+
+                    Tuple.delete_at({:ok, 123}, 2)
+
+                the given type does not have the given index:
+
+                    {:ok, integer()}
+                """}
+    end
   end
 
   describe "maps/structs" do