Initial import

Author: sandeepmistry

GestureToEmoji/ArduinoSketches/Emoji_Button/Emoji_Button.ino

@@ -0,0 +1,92 @@
+/*
+  Emoji Button
+
+  This example sends an emoji character over USB HID when the button is pressed.
+
+  Note: Only macOS and Linux as supported at this time, and the use of
+        #define is generally discouraged in Arduino examples
+
+  The circuit:
+  - Arduino Nano 33 BLE or Arduino Nano 33 BLE Sense board.
+  - Button connected to pin 3 and GND.
+
+  Created by Don Coleman, Sandeep Mistry
+
+  This example code is in the public domain.
+*/
+
+#include <PluggableUSBHID.h>
+#include <USBKeyboard.h>
+
+// Select an OS:
+//#define MACOS // You'll need to enable and select the unicode keyboard: System Preferences -> Input Sources -> + -> Others -> Unicode Hex Input
+//#define LINUX
+
+#if !defined(MACOS) && !defined(LINUX)
+#error "Please select an OS!"
+#endif
+
+// use table: https://apps.timwhitlock.info/emoji/tables/unicode
+const int bicep = 0x1f4aa;
+const int punch = 0x1f44a;
+
+const int buttonPin = 3;
+
+USBKeyboard keyboard;
+
+int previousButtonState = HIGH;
+
+void setup() {
+  pinMode(buttonPin, INPUT_PULLUP);
+}
+
+void loop() {
+  int buttonState = digitalRead(buttonPin);
+
+  if (buttonState != previousButtonState) {
+    if (buttonState == LOW) {
+      // pressed
+      sentUtf8(bicep);
+    } else {
+      // released
+    }
+
+    previousButtonState = buttonState;
+  }
+}
+
+void sentUtf8(unsigned long c) {
+  String s;
+
+#if defined(MACOS)
+  // https://apple.stackexchange.com/questions/183045/how-can-i-type-unicode-characters-without-using-the-mouse
+
+  s = String(utf8ToUtf16(c), HEX);
+
+  for (int i = 0; i < s.length(); i++) {
+    keyboard.key_code(s[i], KEY_ALT);
+  }
+#elif defined(LINUX)
+  s = String(c, HEX);
+
+  keyboard.key_code('u', KEY_CTRL | KEY_SHIFT);
+
+  for (int i = 0; i < s.length(); i++) {
+    keyboard.key_code(s[i]);
+  }
+#endif
+  keyboard.key_code(' ');
+}
+
+// based on https://stackoverflow.com/a/6240819/2020087
+unsigned long utf8ToUtf16(unsigned long in) {
+  unsigned long result;
+
+  in -= 0x10000;
+
+  result |= (in & 0x3ff);
+  result |= (in << 6) & 0x03ff0000;
+  result |= 0xd800dc00;
+
+  return result;
+}

GestureToEmoji/ArduinoSketches/HardwareTest/HardwareTest.ino

@@ -0,0 +1,66 @@
+/*
+  Hardware Test
+
+  This example performs a basic hardware test of the board which includes
+  testing the on-board IMU, LED and external button.
+
+  When the button is pressed the on-board LED will turn on.
+
+  The circuit:
+  - Arduino Nano 33 BLE or Arduino Nano 33 BLE Sense board.
+  - Button connected to pin 3 and GND.
+
+  Created by Don Coleman, Sandeep Mistry
+
+  This example code is in the public domain.
+*/
+
+#include <Arduino_LSM9DS1.h>
+
+const int buttonPin = 3; 
+const int ledPin = LED_BUILTIN;
+
+int buttonState = LOW;  
+int previousButtonState = HIGH;
+
+void setup() {
+  Serial.begin(9600);
+  //while (!Serial);
+  Serial.println("Arduino ML Workshop Hardware Test");
+
+  if (!IMU.begin()) {
+    Serial.println("Failed to initialize IMU!");
+    while (1);
+  }
+
+  // initialize the LED pin as an output:
+  pinMode(ledPin, OUTPUT);
+  // initialize the push button pin as an input with (internal) pullup:
+  pinMode(buttonPin, INPUT_PULLUP);
+}
+
+void loop() {
+  // read the state of the push button pin:
+  buttonState = digitalRead(buttonPin);
+
+  // HIGH and LOW are opposite because of we are using an internal pullup resistor.
+  // LOW is pressed. HIGH is released.
+  
+  if (buttonState == LOW) {
+    // Button is pressed, turn the LED on
+    digitalWrite(ledPin, HIGH);
+    if (buttonState != previousButtonState) {
+      Serial.println("LED is ON");      
+    }
+  } else {
+    // Button is released, turn the LED off
+    digitalWrite(ledPin, LOW);
+    if (buttonState != previousButtonState) {
+      Serial.println("LED is OFF");      
+    }
+  }
+
+  // save the previous state of the button since we only print
+  // the LED status when the state changes
+  previousButtonState = buttonState;
+}

GestureToEmoji/ArduinoSketches/IMU_Capture/IMU_Capture.ino

@@ -0,0 +1,92 @@
+/*
+  IMU Capture
+
+  This example uses the on-board IMU to start reading acceleration and gyroscope
+  data from on-board IMU and prints it to the Serial Monitor for one second
+  when the significant motion is detected.
+
+  You can also use the Serial Plotter to graph the data.
+
+  The circuit:
+  - Arduino Nano 33 BLE or Arduino Nano 33 BLE Sense board.
+
+  Created by Don Coleman, Sandeep Mistry
+  Modified by Dominic Pajak, Sandeep Mistry
+
+  This example code is in the public domain.
+*/
+
+#include <Arduino_LSM9DS1.h>
+
+const float accelerationThreshold = 2.5; // threshold of significant in G's
+const int numSamples = 119;
+
+int samplesRead = numSamples;
+
+void setup() {
+  Serial.begin(9600);
+  while (!Serial);
+
+  if (!IMU.begin()) {
+    Serial.println("Failed to initialize IMU!");
+    while (1);
+  }
+
+  // print the header
+  Serial.println("aX,aY,aZ,gX,gY,gZ");
+}
+
+void loop() {
+  float aX, aY, aZ, gX, gY, gZ;
+
+  // wait for significant motion
+  while (samplesRead == numSamples) {
+    if (IMU.accelerationAvailable()) {
+      // read the acceleration data
+      IMU.readAcceleration(aX, aY, aZ);
+
+      // sum up the absolutes
+      float aSum = fabs(aX) + fabs(aY) + fabs(aZ);
+
+      // check if it's above the threshold
+      if (aSum >= accelerationThreshold) {
+        // reset the sample read count
+        samplesRead = 0;
+        break;
+      }
+    }
+  }
+
+  // check if the all the required samples have been read since
+  // the last time the significant motion was detected
+  while (samplesRead < numSamples) {
+    // check if both new acceleration and gyroscope data is
+    // available
+    if (IMU.accelerationAvailable() && IMU.gyroscopeAvailable()) {
+      // read the acceleration and gyroscope data
+      IMU.readAcceleration(aX, aY, aZ);
+      IMU.readGyroscope(gX, gY, gZ);
+
+      samplesRead++;
+
+      // print the data in CSV format
+      Serial.print(aX, 3);
+      Serial.print(',');
+      Serial.print(aY, 3);
+      Serial.print(',');
+      Serial.print(aZ, 3);
+      Serial.print(',');
+      Serial.print(gX, 3);
+      Serial.print(',');
+      Serial.print(gY, 3);
+      Serial.print(',');
+      Serial.print(gZ, 3);
+      Serial.println();
+
+      if (samplesRead == numSamples) {
+        // add an empty line if it's the last sample
+        Serial.println();
+      }
+    }
+  }
+}