Add example

Author: pennam

Diff for: examples/ArduinoIoTCloud-Client/ArduinoIoTCloud-Client.ino

@@ -0,0 +1,65 @@
+/*
+  This sketch demonstrates how to exchange data between your board and the Arduino IoT Cloud.
+
+  * Connect a potentiometer (or other analog sensor) to A0.
+  * When the potentiometer (or sensor) value changes the data is sent to the Cloud.
+  * When you flip the switch in the Cloud dashboard the onboard LED lights gets turned ON or OFF.
+
+  IMPORTANT:
+  This sketch works with WiFi, GSM, NB, Ethernet and Lora enabled boards supported by Arduino IoT Cloud.
+  On a LoRa board, if it is configured as a class A device (default and preferred option), values from Cloud dashboard are received
+  only after a value is sent to Cloud.
+
+  The full list of compatible boards can be found here:
+   - https://github.com/arduino-libraries/ArduinoIoTCloud#what
+*/
+
+#include "arduino_secrets.h"
+#include "thingProperties.h"
+
+#if !defined(LED_BUILTIN) && !defined(ARDUINO_NANO_ESP32)
+static int const LED_BUILTIN = 2;
+#endif
+
+void setup() {
+  /* Initialize serial and wait up to 5 seconds for port to open */
+  Serial.begin(9600);
+  while(!Serial) {}
+
+  /* Configure LED pin as an output */
+  pinMode(LED_BUILTIN, OUTPUT);
+
+  /* This function takes care of connecting your sketch variables to the ArduinoIoTCloud object */
+  initProperties();
+
+  Serial.print("Attempting to connect to SSID: ");
+  Serial.println(SECRET_SSID);
+  unsigned long start = millis();
+  WiFi.begin(SECRET_SSID, SECRET_PASS);
+  while ((WiFi.status() != WL_CONNECTED) && ((millis() - start) < 3000)) {
+    delay(100);
+  }
+  Serial.println("WiFi connected");
+
+  /* Initialize Arduino IoT Cloud library */
+  ArduinoCloud.begin(client, udp);
+
+  setDebugMessageLevel(DBG_VERBOSE);
+  ArduinoCloud.printDebugInfo();
+}
+
+void loop() {
+  ArduinoCloud.update();
+  potentiometer = analogRead(A0);
+  seconds = millis() / 1000;
+  delay(100);
+}
+
+/*
+ * 'onLedChange' is called when the "led" property of your Thing changes
+ */
+void onLedChange() {
+  Serial.print("LED set to ");
+  Serial.println(led);
+  digitalWrite(LED_BUILTIN, led);
+}

Diff for: examples/ArduinoIoTCloud-Client/arduino_secrets.h

@@ -0,0 +1,45 @@
+#include <ArduinoIoTCloud.h>
+#include <Arduino_ConnectionHandler.h>
+
+/* A complete list of supported boards with WiFi is available here:
+ * https://github.com/arduino-libraries/ArduinoIoTCloud/#what
+ */
+#if defined(BOARD_HAS_WIFI)
+  #define SECRET_SSID ""
+  #define SECRET_PASS ""
+#endif
+
+/* ESP8266 ESP32*/
+#if defined(BOARD_HAS_SECRET_KEY)
+  #define SECRET_DEVICE_KEY ""
+#endif
+
+/* MKR GSM 1400 */
+#if defined(BOARD_HAS_GSM)
+  #define SECRET_PIN ""
+  #define SECRET_APN ""
+  #define SECRET_LOGIN ""
+  #define SECRET_PASS ""
+#endif
+
+/* MKR WAN 1300/1310 */
+#if defined(BOARD_HAS_LORA)
+  #define SECRET_APP_EUI ""
+  #define SECRET_APP_KEY ""
+#endif
+
+/* MKR NB 1500 */
+#if defined(BOARD_HAS_NB)
+  #define SECRET_PIN ""
+  #define SECRET_APN ""
+  #define SECRET_LOGIN ""
+  #define SECRET_PASS ""
+#endif
+
+/* Portenta H7 + Ethernet shield */
+#if defined(BOARD_HAS_ETHERNET)
+  #define SECRET_OPTIONAL_IP ""
+  #define SECRET_OPTIONAL_DNS ""
+  #define SECRET_OPTIONAL_GATEWAY ""
+  #define SECRET_OPTIONAL_NETMASK ""
+#endif

Diff for: examples/ArduinoIoTCloud-Client/thingProperties.h

@@ -0,0 +1,36 @@
+#if defined(BOARD_HAS_WIFI)
+  WiFiClient client;
+  WiFiUDP udp;
+#elif defined(BOARD_HAS_GSM)
+#elif defined(BOARD_HAS_LORA)
+#elif defined(BOARD_HAS_NB)
+#elif defined(BOARD_HAS_ETHERNET)
+#else
+  #error "Please check Arduino IoT Cloud supported boards list: https://github.com/arduino-libraries/ArduinoIoTCloud/#what"
+#endif
+
+#if defined(BOARD_HAS_SECRET_KEY)
+  #define BOARD_ID ""
+#endif
+
+void onLedChange();
+
+bool led;
+int potentiometer;
+int seconds;
+
+void initProperties() {
+#if defined(BOARD_HAS_SECRET_KEY)
+  ArduinoCloud.setBoardId(BOARD_ID);
+  ArduinoCloud.setSecretDeviceKey(SECRET_DEVICE_KEY);
+#endif
+#if defined(BOARD_HAS_WIFI) || defined(BOARD_HAS_GSM) || defined(BOARD_HAS_NB) || defined(BOARD_HAS_ETHERNET)
+  ArduinoCloud.addProperty(led, Permission::Write).onUpdate(onLedChange);
+  ArduinoCloud.addProperty(potentiometer, Permission::Read).publishOnChange(10);
+  ArduinoCloud.addProperty(seconds, Permission::Read).publishOnChange(1);
+#elif defined(BOARD_HAS_LORA)
+  ArduinoCloud.addProperty(led, 1, READWRITE, ON_CHANGE, onLedChange);
+  ArduinoCloud.addProperty(potentiometer, 2, READ, ON_CHANGE);
+  ArduinoCloud.addProperty(seconds, 3, READ, 5 * MINUTES);
+#endif
+}