cordio: lower power polling with timeout #15

sandeepmistry · 2019-08-28T21:35:16Z

I've been testing this with the Examples -> Peripheral -> LEDCallback example, with two changes:

Removing: while (!Serial); from setup()
Changing BLE.poll(); in loop() to BLE.poll(60000);

Unfortunately, in my brief testing it doesn't seem to be lower power (using a USB supply input).

@facchinm any thoughts on this?

sandeepmistry · 2019-09-09T16:54:29Z

Ok, so I've done some more testing on this, setup is cutting the 3.3V pad on the back and supplying a direct 3.3V input.

This reference sketch, seems to consume ~0.93 mA:

void setup() {
  pinMode(LED_PWR, OUTPUT);
  digitalWrite(LED_PWR, LOW);
}

void loop() {
  // put your main code here, to run repeatedly:
  delay(60 * 1000);
}

With and without this patch, the following sketch is ~6.95 mA:

/*
  Callback LED

  This example creates a BLE peripheral with service that contains a
  characteristic to control an LED. The callback features of the
  library are used.

  The circuit:
  - Arduino MKR WiFi 1010, Arduino Uno WiFi Rev2 board, Arduino Nano 33 IoT,
    Arduino Nano 33 BLE, or Arduino Nano 33 BLE Sense board.

  You can use a generic BLE central app, like LightBlue (iOS and Android) or
  nRF Connect (Android), to interact with the services and characteristics
  created in this sketch.

  This example code is in the public domain.
*/

#include <ArduinoBLE.h>

BLEService ledService("19B10000-E8F2-537E-4F6C-D104768A1214"); // create service

// create switch characteristic and allow remote device to read and write
BLEByteCharacteristic switchCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);

const int ledPin = LED_BUILTIN; // pin to use for the LED

void setup() {
  Serial.begin(9600);
//  while (!Serial);


  pinMode(LED_PWR, OUTPUT);
  digitalWrite(LED_PWR, LOW);
  
  pinMode(ledPin, OUTPUT); // use the LED pin as an output

  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");

    while (1);
  }

  // set the local name peripheral advertises
  BLE.setLocalName("LEDCallback");
  // set the UUID for the service this peripheral advertises
  BLE.setAdvertisedService(ledService);

  BLE.setAdvertisingInterval(1600);

  // add the characteristic to the service
  ledService.addCharacteristic(switchCharacteristic);

  // add service
  BLE.addService(ledService);

  // assign event handlers for connected, disconnected to peripheral
  BLE.setEventHandler(BLEConnected, blePeripheralConnectHandler);
  BLE.setEventHandler(BLEDisconnected, blePeripheralDisconnectHandler);

  // assign event handlers for characteristic
  switchCharacteristic.setEventHandler(BLEWritten, switchCharacteristicWritten);
  // set an initial value for the characteristic
  switchCharacteristic.setValue(0);

  // start advertising
  BLE.advertise();

  Serial.println(("Bluetooth device active, waiting for connections..."));
}

void loop() {
  // poll for BLE events
  BLE.poll();
}

void blePeripheralConnectHandler(BLEDevice central) {
  // central connected event handler
  Serial.print("Connected event, central: ");
  Serial.println(central.address());
}

void blePeripheralDisconnectHandler(BLEDevice central) {
  // central disconnected event handler
  Serial.print("Disconnected event, central: ");
  Serial.println(central.address());
}

void switchCharacteristicWritten(BLEDevice central, BLECharacteristic characteristic) {
  // central wrote new value to characteristic, update LED
  Serial.print("Characteristic event, written: ");

  if (switchCharacteristic.value()) {
    Serial.println("LED on");
    digitalWrite(ledPin, HIGH);
  } else {
    Serial.println("LED off");
    digitalWrite(ledPin, LOW);
  }
}

So I think the patch is fine to merge, but still think something in Cordio is consuming power.

cc/ @facchinm

…entFlags

sandeepmistry · 2019-09-10T19:25:37Z

src/utility/HCICordioTransport.cpp

@@ -103,6 +103,9 @@ extern "C" void wsf_mbed_ble_signal_event(void)
 }
 #endif //CORDIO_ZERO_COPY_HCI

+#undef WSF_MS_PER_TICK
+#define WSF_MS_PER_TICK 10


@facchinm I'm not sure if this should be changed in the core instead?

WSF_MS_PER_TICK defaults to 10ms: https://github.com/arduino/ArduinoCore-nRF528x-mbedos/blob/beac74ca3cd9d07363f66cf9cda6b143e4385cd2/cores/arduino/mbed/features/FEATURE_BLE/targets/TARGET_CORDIO/stack/wsf/include/wsf_timer.h#L40 - but in the Nano 33 BLE variant it's set to 1 ms for some reason (https://github.com/arduino/ArduinoCore-nRF528x-mbedos/blob/a1816cd20de39ffc03a9cfd6b378e7b63b210a89/variants/ARDUINO_NANO33BLE/mbed_config.h#L336).

Alternatively I think we can rename it in the file, as it doesn't seem to be compiled in mbed?

Renaming it here should work just fine.

@facchinm great, just pushed. This is ready for review now.

Later on we could be a bit smarter and change the poll interval dynamically based on the connection, advertising or scan intervals. However, let's see how feedback from customers goes.

sandeepmistry · 2019-09-10T19:27:57Z

@facchinm so much better results with the last commit I've pushed, the following sketch uses ~1.6 mA of current while advertising and powered directly via 3.3V (jumper sliced):

/*
  Callback LED

  This example creates a BLE peripheral with service that contains a
  characteristic to control an LED. The callback features of the
  library are used.

  The circuit:
  - Arduino MKR WiFi 1010, Arduino Uno WiFi Rev2 board, Arduino Nano 33 IoT,
    Arduino Nano 33 BLE, or Arduino Nano 33 BLE Sense board.

  You can use a generic BLE central app, like LightBlue (iOS and Android) or
  nRF Connect (Android), to interact with the services and characteristics
  created in this sketch.

  This example code is in the public domain.
*/

#include <ArduinoBLE.h>

BLEService ledService("19B10000-E8F2-537E-4F6C-D104768A1214"); // create service

// create switch characteristic and allow remote device to read and write
BLEByteCharacteristic switchCharacteristic("19B10001-E8F2-537E-4F6C-D104768A1214", BLERead | BLEWrite);

const int ledPin = LED_BUILTIN; // pin to use for the LED

void setup() {
  Serial.begin(9600);
//  while (!Serial);

  pinMode(LED_PWR, OUTPUT);
  digitalWrite(LED_PWR, LOW);
  
  pinMode(ledPin, OUTPUT); // use the LED pin as an output

  // begin initialization
  if (!BLE.begin()) {
    Serial.println("starting BLE failed!");

    while (1);
  }

  // set the local name peripheral advertises
  BLE.setLocalName("LEDCallback");
  // set the UUID for the service this peripheral advertises
  BLE.setAdvertisedService(ledService);

//  BLE.setAdvertisingInterval(1600);

  // add the characteristic to the service
  ledService.addCharacteristic(switchCharacteristic);

  // add service
  BLE.addService(ledService);

  // assign event handlers for connected, disconnected to peripheral
  BLE.setEventHandler(BLEConnected, blePeripheralConnectHandler);
  BLE.setEventHandler(BLEDisconnected, blePeripheralDisconnectHandler);

  // assign event handlers for characteristic
  switchCharacteristic.setEventHandler(BLEWritten, switchCharacteristicWritten);
  // set an initial value for the characteristic
  switchCharacteristic.setValue(0);

  // start advertising
  BLE.advertise();

  Serial.println(("Bluetooth device active, waiting for connections..."));
}

void loop() {
  // poll for BLE events
  BLE.poll(10000);
}

void blePeripheralConnectHandler(BLEDevice central) {
  // central connected event handler
  Serial.print("Connected event, central: ");
  Serial.println(central.address());
}

void blePeripheralDisconnectHandler(BLEDevice central) {
  // central disconnected event handler
  Serial.print("Disconnected event, central: ");
  Serial.println(central.address());
}

void switchCharacteristicWritten(BLEDevice central, BLECharacteristic characteristic) {
  // central wrote new value to characteristic, update LED
  Serial.print("Characteristic event, written: ");

  if (switchCharacteristic.value()) {
    Serial.println("LED on");
    digitalWrite(ledPin, HIGH);
  } else {
    Serial.println("LED off");
    digitalWrite(ledPin, LOW);
  }
}

ixj111 · 2019-09-21T15:14:43Z

Does the code put the board into sleep between the polling intervals?

sandeepmistry · 2019-09-23T13:06:38Z

Hi @ixj111,

Does the code put the board into sleep between the polling intervals?

The behaviour is as follows for the Nano 33 BLE: BLE.poll(10000) will do a low power wait for the sketch code for 10s or until a radio event occurs. Please note there will still be a link layer thread running that might prevent sleep mode.

ixj111 · 2019-09-23T15:17:40Z

Sandeep, thank you for the reply. I tested the code by BLE.setAdvertisingInterval(5000)
and BLE.poll(300000) to make it a much longer sleep. Then I used BLE apps on my smartphone to see if the board still advertises during the sleep. I discovered the device all the time in the smartphone apps like the device doesn't go to sleep at all. Am I missing anything?

ixj111 · 2019-10-15T18:18:26Z

Is it possible to share a picture of the board setup (jumper sliced)?

sandeepmistry · 2019-11-11T20:25:28Z

@ixj111

I discovered the device all the time in the smartphone apps like the device doesn't go to sleep at all. Am I missing anything?

This is the intended behaviour there is no sleep, the power consumption is just lower between radio events.

Is it possible to share a picture of the board setup (jumper sliced)?

I don't have the board with me, however here's an annotated photo. You will need to cut the trace and supply 3.3V to the right pad. Including when programming.

SteenPetersen · 2020-02-19T09:48:01Z

For those asking to see what 'cut the trace' means. You need to cut the connection between the two jumpers on the bottom of the board as mentioned (see picture). To test if the connection has been severed, put in the USB cable again. Notice that it no longer powers the board, if it does, you need to cut a bit deeper. You will now need to power the board using the 3.3v pin, even when uploading code.

If you later wish to go back to using the board through the USB cable, simply solder up the joint that was severed by the cut.

alexisicte · 2020-02-19T09:59:15Z

For those asking to see what 'cut the trace' means. You need to cut the connection between the two jumpers on the bottom of the board as mentioned (see picture). To test if the connection has been severed, put in the USB cable again. Notice that it no longer powers the board, if it does, you need to cut a bit deeper. You will now need to power the board using the 3.3v pin, even when uploading code.

If you later wish to go back to using the board through the USB cable, simply solder up the joint that was severed by the cut.

If you want to keep the above configuration and flash the board again, you have to solder the Vusb traces and power the board using the 3.3v pin. Is that true?

per1234 · 2020-02-19T14:14:59Z

you have to solder the Vusb traces and power the board using the 3.3v pin. Is that true?

You don't need to solder the VUSB jumper. That is only used to connect Vusb to the +5V pin (it's disconnected by default to emphasize to the user that, unlike the classic Nano, this is a 3.3 V board). To upload to the Nano 33 BLE after cutting the 3.3 V jumper, you only need to power the board via the 3.3 V pin, connect the USB cable, and upload as usual. You will not be able to upload with only the USB cable attached because the nRF52840 is no longer powered via USB.

SteenPetersen · 2020-02-20T11:22:17Z

If you later wish to go back to using the board through the USB cable, simply solder up the joint that was severed by the cut.

Sorry I wasn't clear here - yes you can still use the USB cable after the cut, it simply won't power the board. You will need to do that by supplying power to the 3.3v pin. If you wish for the USB cable to power the board at a later stage you can solder the cut connection.

whofmeis · 2020-04-26T14:39:18Z

When using the 3.3v pin, do I still need to provide 5v over the USB cable when I want to program the Arduino (33 BLE Sense)? No matter what I do, I can't get my computer to detect the Arduino after powering it from the 3.3v pin - it doesn't even show up under USB devices. However, the BUILT_IN_LED is pulsing when I connect the USB cable to the computer, so I suppose that the Arduino seems to detect being connected to a USB host.

SteenPetersen · 2020-04-26T14:49:06Z

When using the 3.3v pin, do I still need to provide 5v over the USB cable when I want to program the Arduino (33 BLE Sense)? No matter what I do, I can't get my computer to detect the Arduino after powering it from the 3.3v pin - it doesn't even show up under USB devices. However, the BUILT_IN_LED is pulsing when I connect the USB cable to the computer, so I suppose that the Arduino seems to detect being connected to a USB host.

It will still recognize the Arduino it will simply not be able to power the board, so you will need to provide it with a power source somehow. Alternatively, you might want to try putting the board into 'development mode' by pressing the 'reset' button twice in quick succession.

whofmeis · 2020-04-26T14:57:24Z

I'm powering it with a 3v3 LDO, which is powered through the same USB cable I'm connecting the Arduino to the computer with. I can see that the Arduino does enter the development mode, but unfortunately, it still don't show up in the device list at all.

SteenPetersen · 2020-04-26T21:38:53Z

The power from the USB will no longer reach the MCU once the cut has been made. So your power source will need to come in from the 3.3 pin.

gbar90 · 2020-05-21T18:57:49Z

Hi, I was wondering if there is any news on this.
I tried the "LEDCallback" example code provided by @sandeepmistry on an Arduino Nano 33 BLE Sense powered directly via 3.3V (jumper sliced) with 3V. I still get a current of ca. 8mA.
I wonder if there is a way to send everything (mainly the NINA module and the nrf chip I guess) to deep sleep on this board. I want to measure every few minutes and save as much power as possible.
Thanks

jaredmaks · 2020-11-27T09:59:57Z

Hi, I was wondering if there is any news on this.
I tried the "LEDCallback" example code provided by @sandeepmistry on an Arduino Nano 33 BLE Sense powered directly via 3.3V (jumper sliced) with 3V. I still get a current of ca. 8mA.
I wonder if there is a way to send everything (mainly the NINA module and the nrf chip I guess) to deep sleep on this board. I want to measure every few minutes and save as much power as possible.
Thanks

You need to update the ArduinoBLE library on your IDE. The library might be old and not having new commits for your case.

gbar90 · 2020-11-27T10:50:36Z

Hey billiyz,
I haven't tried recently, the libraries might be updated.
I worked around it by powering the nfr52 down and waiting 1 min for an external wake up. This way it runs for months with a coin cell battery, measuring every minute.

void gotosleep() {

  // low power comparator setup to wake-up when the capacitor is discharged to 1/16 of VIN
  NRF_LPCOMP->PSEL=1; //select AIN3 = PIN_A1 = P0.05
  NRF_LPCOMP->REFSEL=8; // VDD * 1/16 selected as reference
  NRF_LPCOMP->ENABLE=1;
  NRF_LPCOMP->TASKS_START=1;
  while(!NRF_LPCOMP->EVENTS_READY){}

  NRF_POWER->SYSTEMOFF = 1;

}

reniar1 · 2023-05-28T23:46:04Z

Hey guys,

I am using the Arduino nano 33 ble and I am powering it with 3.3 volt and I cut the jumper to make that possible.

However if I start the board (peripheral) with 3v3 it will not be visible to the clients when they scan for bluetooth.

However if i plugin the 5v cable (micro usb) it will be visible, I can then plug it out again and it will still be visible.

It is like if the Arduino nano 33 ble need the 5v initially provided through the usb port to start up and then it can be constantly powered by 3v3.

Do you have any knowledge about this behaviour?

Idealy I would like to power the board with 3v3 and then see it (as an peripharal device) on my clients withoput having to initalize it by pluggin in the 5v cabl one time.

Hsubtnarg · 2024-01-18T06:41:27Z

Did this ever make it into the library as the above code still draws ~7mA and looking at the code in the library it does not seem to have changed (I have the latest version 1.3.6). But if I change WSF_MS_PER_TICK in mbed_config.h to 10, the same code only draws ~2mA

cordio: use signals to wait for new HCI data when polling

3be2231

sandeepmistry mentioned this pull request Sep 9, 2019

Best way to observe a peripheral’s RSSI #25

Closed

Use rtos::ThisThread::sleep_for(ms) for sleeping > 1 ms, and rtos::Ev…

9b35ebd

…entFlags

sandeepmistry commented Sep 10, 2019

View reviewed changes

Rename WSF_MS_PER_TICK to CORDIO_TRANSPORT_WSF_MS_PER_TICK

8f4bea8

sandeepmistry changed the title ~~[DO NOT MERGE] cordio: use signals to wait for new HCI data when polling~~ cordio: lower power polling with timeout Sep 11, 2019

sandeepmistry requested a review from facchinm September 11, 2019 13:22

facchinm approved these changes Sep 19, 2019

View reviewed changes

sandeepmistry merged commit 5e44386 into arduino-libraries:master Sep 19, 2019

facchinm mentioned this pull request Oct 14, 2019

No low power mode possible #37

Closed

sandeepmistry mentioned this pull request Nov 29, 2019

Cordio: BLE thread loop fixes #44

Merged

arduino-libraries deleted a comment from Tazrih Oct 25, 2021

This comment has been minimized.

Sign in to view

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

cordio: lower power polling with timeout #15

cordio: lower power polling with timeout #15

sandeepmistry commented Aug 28, 2019

sandeepmistry commented Sep 9, 2019 •

edited

Loading

sandeepmistry Sep 10, 2019

sandeepmistry Sep 10, 2019

facchinm Sep 11, 2019

sandeepmistry Sep 11, 2019

sandeepmistry commented Sep 10, 2019

ixj111 commented Sep 21, 2019

sandeepmistry commented Sep 23, 2019

ixj111 commented Sep 23, 2019

ixj111 commented Oct 15, 2019

sandeepmistry commented Nov 11, 2019

SteenPetersen commented Feb 19, 2020 •

edited

Loading

alexisicte commented Feb 19, 2020

per1234 commented Feb 19, 2020

SteenPetersen commented Feb 20, 2020

whofmeis commented Apr 26, 2020

SteenPetersen commented Apr 26, 2020

whofmeis commented Apr 26, 2020

SteenPetersen commented Apr 26, 2020

gbar90 commented May 21, 2020

jaredmaks commented Nov 27, 2020

gbar90 commented Nov 27, 2020

This comment has been minimized.

reniar1 commented May 28, 2023

Hsubtnarg commented Jan 18, 2024

cordio: lower power polling with timeout #15

cordio: lower power polling with timeout #15

Conversation

sandeepmistry commented Aug 28, 2019

sandeepmistry commented Sep 9, 2019 • edited Loading

sandeepmistry Sep 10, 2019

Choose a reason for hiding this comment

sandeepmistry Sep 10, 2019

Choose a reason for hiding this comment

facchinm Sep 11, 2019

Choose a reason for hiding this comment

sandeepmistry Sep 11, 2019

Choose a reason for hiding this comment

sandeepmistry commented Sep 10, 2019

ixj111 commented Sep 21, 2019

sandeepmistry commented Sep 23, 2019

ixj111 commented Sep 23, 2019

ixj111 commented Oct 15, 2019

sandeepmistry commented Nov 11, 2019

SteenPetersen commented Feb 19, 2020 • edited Loading

alexisicte commented Feb 19, 2020

per1234 commented Feb 19, 2020

SteenPetersen commented Feb 20, 2020

whofmeis commented Apr 26, 2020

SteenPetersen commented Apr 26, 2020

whofmeis commented Apr 26, 2020

SteenPetersen commented Apr 26, 2020

gbar90 commented May 21, 2020

jaredmaks commented Nov 27, 2020

gbar90 commented Nov 27, 2020

This comment has been minimized.

reniar1 commented May 28, 2023

Hsubtnarg commented Jan 18, 2024

sandeepmistry commented Sep 9, 2019 •

edited

Loading

SteenPetersen commented Feb 19, 2020 •

edited

Loading