archrelease: copy trunk to community-staging-x86_64

git-svn-id: file:///srv/repos/svn-community/svn@744663 9fca08f4-af9d-4005-b8df-a31f2cc04f65

Author: felixonmars

haskell-pipes-http/repos/community-staging-x86_64/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <[email protected]>
+# Contributor: Arch Haskell Team <[email protected]>
+
+_hkgname=pipes-http
+pkgname=haskell-pipes-http
+pkgver=1.0.6
+pkgrel=234
+pkgdesc="HTTP client with pipes interface"
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-http-client" "haskell-http-client-tls" "haskell-pipes")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b58e5751863d79c08066846fb5959870cf6673e27297acd3b7980b209321a636fdf564c4c08666313c81f7c6c55f4d1307892bc6a59a01a025a87436d5591774')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *0.7/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}