main.cpp

#include "main.hpp"
#include "FS.h"
#include "SPIFFS.h"

void setup() 
{
  Serial.begin(115200);
  // Serial.setDebugOutput(true);

  Serial.println();
  Serial.println();
  Serial.println();

  WiFi.mode(WIFI_STA);
  WiFiMulti.addAP(SSID, PASS);

  // wait for WiFi connection
  Serial.print("Waiting for WiFi to connect...");
  while ((WiFiMulti.run() != WL_CONNECTED)) {
    Serial.print(".");
  }
  Serial.println(" connected");

  setClock();
}

void loop() 
{
  WiFiClientSecure *client = new WiFiClientSecure;


  if(client)
  {
    client->setUseCertBundle(true);

    bool bundleLoaded = true;

    // Start SPIFFS and load partition
    if(!SPIFFS.begin()) {
        Serial.println("Could not start SPIFFS and load partition");
        bundleLoaded = false;
    }


    // Load bundle from SPIFFS
    File file = SPIFFS.open("/cert/x509_crt_bundle.bin", "r");
    if(!file) {
        Serial.println("Could not load bundle from SPIFFS");
        bundleLoaded = false;
    }


    // Load loadCertBundle into WiFiClientSecure
    if(file && file.size() > 0) {
        if(!client->loadCertBundle(file, file.size())){
            Serial.println("WiFiClientSecure: could not load bundle");
            bundleLoaded = false;
        }
    }

    
    if(bundleLoaded){
      // Add a scoping block for HTTPClient https to make sure it is destroyed before WiFiClientSecure *client is 
      HTTPClient https;
  
      Serial.print("[HTTPS] begin...\n");
      if (https.begin(*client, SSL_TEST_URL)) {  // HTTPS
        Serial.print("[HTTPS] GET...\n");
        // start connection and send HTTP header
        int httpCode = https.GET();
  
        // httpCode will be negative on error
        if (httpCode > 0) {
          // HTTP header has been send and Server response header has been handled
          Serial.printf("[HTTPS] GET... code: %d\n", httpCode);
  
          // file found at server
          if (httpCode == HTTP_CODE_OK || httpCode == HTTP_CODE_MOVED_PERMANENTLY) {
            String payload = https.getString();
            Serial.println(payload);
          }
        } else {
          Serial.printf("[HTTPS] GET... failed, error: %s\n", https.errorToString(httpCode).c_str());
        }
  
        https.end();
      } else {
        Serial.printf("[HTTPS] Unable to connect\n");
      }

      // End extra scoping block
    }
  
    delete client;
  } else {
    Serial.println("Unable to create client");
  }

  Serial.println();
  Serial.println("Waiting 10s before the next round...");
  delay(60000);
}

void setClock()
{
  configTime(0, 0, "pool.ntp.org", "time.nist.gov");

  Serial.print(F("Waiting for NTP time sync: "));
  time_t nowSecs = time(nullptr);
  while (nowSecs < 8 * 3600 * 2) {
    delay(500);
    Serial.print(F("."));
    yield();
    nowSecs = time(nullptr);
  }

  Serial.println();
  struct tm timeinfo;
  gmtime_r(&nowSecs, &timeinfo);
  Serial.print(F("Current time: "));
  Serial.print(asctime(&timeinfo));
}