diff --git a/reactive/kotlinx-coroutines-reactive/build.gradle b/reactive/kotlinx-coroutines-reactive/build.gradle
deleted file mode 100644
index ad97c63f45..0000000000
--- a/reactive/kotlinx-coroutines-reactive/build.gradle
+++ /dev/null
@@ -1,34 +0,0 @@
-/*
- * Copyright 2016-2020 JetBrains s.r.o. Use of this source code is governed by the Apache 2.0 license.
- */
-
-dependencies {
-    compile "org.reactivestreams:reactive-streams:$reactive_streams_version"
-    testCompile "org.reactivestreams:reactive-streams-tck:$reactive_streams_version"
-}
-
-task testNG(type: Test) {
-    useTestNG()
-    reports.html.destination = file("$buildDir/reports/testng")
-    include '**/*ReactiveStreamTckTest.*'
-    // Skip testNG when tests are filtered with --tests, otherwise it simply fails
-    onlyIf {
-        filter.includePatterns.isEmpty()
-    }
-    doFirst {
-        // Classic gradle, nothing works without doFirst
-        println "TestNG tests: ($includes)"
-    }
-}
-
-test {
-    dependsOn(testNG)
-    reports.html.destination = file("$buildDir/reports/junit")
-}
-
-tasks.withType(dokka.getClass()) {
-    externalDocumentationLink {
-        url = new URL("https://www.reactive-streams.org/reactive-streams-$reactive_streams_version-javadoc/")
-        packageListUrl = projectDir.toPath().resolve("package.list").toUri().toURL()
-    }
-}
diff --git a/reactive/kotlinx-coroutines-reactive/build.gradle.kts b/reactive/kotlinx-coroutines-reactive/build.gradle.kts
new file mode 100644
index 0000000000..a4afe46569
--- /dev/null
+++ b/reactive/kotlinx-coroutines-reactive/build.gradle.kts
@@ -0,0 +1,43 @@
+/*
+ * Copyright 2016-2020 JetBrains s.r.o. Use of this source code is governed by the Apache 2.0 license.
+ */
+
+import org.jetbrains.dokka.DokkaConfiguration.ExternalDocumentationLink
+import org.jetbrains.dokka.gradle.DokkaTask
+import java.net.URL
+
+val reactiveStreamsVersion = property("reactive_streams_version")
+
+dependencies {
+    compile("org.reactivestreams:reactive-streams:$reactiveStreamsVersion")
+    testCompile("org.reactivestreams:reactive-streams-tck:$reactiveStreamsVersion")
+}
+
+tasks {
+    val testNG = register<Test>("testNG") {
+        useTestNG()
+        reports.html.destination = buildDir.resolve("/reports/testng")
+        include("**/*ReactiveStreamTckTest.*")
+        // Skip testNG when tests are filtered with --tests, otherwise it simply fails
+        onlyIf {
+            filter.includePatterns.isEmpty()
+        }
+        doFirst {
+            // Classic gradle, nothing works without doFirst
+            println("TestNG tests: ($includes)")
+        }
+    }
+
+    named<Test>("test") {
+        reports.html.destination = buildDir.resolve("/reports/junit")
+
+        dependsOn(testNG)
+    }
+
+    withType<DokkaTask>().configureEach {
+        externalDocumentationLink(delegateClosureOf<ExternalDocumentationLink.Builder> {
+            url = URL("https://www.reactive-streams.org/reactive-streams-$reactiveStreamsVersion-javadoc/")
+            packageListUrl = projectDir.toPath().resolve("package.list").toUri().toURL()
+        })
+    }
+}