|
| 1 | +""" |
| 2 | +Cython implementations for internal ExtensionArrays. |
| 3 | +""" |
| 4 | +cimport cython |
| 5 | + |
| 6 | +import numpy as np |
| 7 | + |
| 8 | +cimport numpy as cnp |
| 9 | +from numpy cimport ndarray |
| 10 | + |
| 11 | +cnp.import_array() |
| 12 | + |
| 13 | + |
| 14 | +@cython.freelist(16) |
| 15 | +cdef class NDArrayBacked: |
| 16 | + """ |
| 17 | + Implementing these methods in cython improves performance quite a bit. |
| 18 | +
|
| 19 | + import pandas as pd |
| 20 | +
|
| 21 | + from pandas._libs.arrays import NDArrayBacked as cls |
| 22 | +
|
| 23 | + dti = pd.date_range("2016-01-01", periods=3) |
| 24 | + dta = dti._data |
| 25 | + arr = dta._ndarray |
| 26 | +
|
| 27 | + obj = cls._simple_new(arr, arr.dtype) |
| 28 | +
|
| 29 | + # for foo in [arr, dta, obj]: ... |
| 30 | +
|
| 31 | + %timeit foo.copy() |
| 32 | + 299 ns ± 30 ns per loop # <-- arr underlying ndarray (for reference) |
| 33 | + 530 ns ± 9.24 ns per loop # <-- dta with cython NDArrayBacked |
| 34 | + 1.66 µs ± 46.3 ns per loop # <-- dta without cython NDArrayBacked |
| 35 | + 328 ns ± 5.29 ns per loop # <-- obj with NDArrayBacked.__cinit__ |
| 36 | + 371 ns ± 6.97 ns per loop # <-- obj with NDArrayBacked._simple_new |
| 37 | +
|
| 38 | + %timeit foo.T |
| 39 | + 125 ns ± 6.27 ns per loop # <-- arr underlying ndarray (for reference) |
| 40 | + 226 ns ± 7.66 ns per loop # <-- dta with cython NDArrayBacked |
| 41 | + 911 ns ± 16.6 ns per loop # <-- dta without cython NDArrayBacked |
| 42 | + 215 ns ± 4.54 ns per loop # <-- obj with NDArrayBacked._simple_new |
| 43 | +
|
| 44 | + """ |
| 45 | + # TODO: implement take in terms of cnp.PyArray_TakeFrom |
| 46 | + # TODO: implement concat_same_type in terms of cnp.PyArray_Concatenate |
| 47 | + |
| 48 | + cdef: |
| 49 | + readonly ndarray _ndarray |
| 50 | + readonly object _dtype |
| 51 | + |
| 52 | + def __init__(self, ndarray values, object dtype): |
| 53 | + self._ndarray = values |
| 54 | + self._dtype = dtype |
| 55 | + |
| 56 | + @classmethod |
| 57 | + def _simple_new(cls, ndarray values, object dtype): |
| 58 | + cdef: |
| 59 | + NDArrayBacked obj |
| 60 | + obj = NDArrayBacked.__new__(cls) |
| 61 | + obj._ndarray = values |
| 62 | + obj._dtype = dtype |
| 63 | + return obj |
| 64 | + |
| 65 | + cpdef NDArrayBacked _from_backing_data(self, ndarray values): |
| 66 | + """ |
| 67 | + Construct a new ExtensionArray `new_array` with `arr` as its _ndarray. |
| 68 | +
|
| 69 | + This should round-trip: |
| 70 | + self == self._from_backing_data(self._ndarray) |
| 71 | + """ |
| 72 | + # TODO: re-reuse simple_new if/when it can be cpdef |
| 73 | + cdef: |
| 74 | + NDArrayBacked obj |
| 75 | + obj = NDArrayBacked.__new__(type(self)) |
| 76 | + obj._ndarray = values |
| 77 | + obj._dtype = self._dtype |
| 78 | + return obj |
| 79 | + |
| 80 | + cpdef __setstate__(self, state): |
| 81 | + if isinstance(state, dict): |
| 82 | + if "_data" in state: |
| 83 | + data = state.pop("_data") |
| 84 | + elif "_ndarray" in state: |
| 85 | + data = state.pop("_ndarray") |
| 86 | + else: |
| 87 | + raise ValueError |
| 88 | + self._ndarray = data |
| 89 | + self._dtype = state.pop("_dtype") |
| 90 | + |
| 91 | + for key, val in state.items(): |
| 92 | + setattr(self, key, val) |
| 93 | + elif isinstance(state, tuple): |
| 94 | + if len(state) != 3: |
| 95 | + if len(state) == 1 and isinstance(state[0], dict): |
| 96 | + self.__setstate__(state[0]) |
| 97 | + return |
| 98 | + raise NotImplementedError(state) |
| 99 | + |
| 100 | + data, dtype = state[:2] |
| 101 | + if isinstance(dtype, np.ndarray): |
| 102 | + dtype, data = data, dtype |
| 103 | + self._ndarray = data |
| 104 | + self._dtype = dtype |
| 105 | + |
| 106 | + if isinstance(state[2], dict): |
| 107 | + for key, val in state[2].items(): |
| 108 | + setattr(self, key, val) |
| 109 | + else: |
| 110 | + raise NotImplementedError(state) |
| 111 | + else: |
| 112 | + raise NotImplementedError(state) |
| 113 | + |
| 114 | + def __len__(self) -> int: |
| 115 | + return len(self._ndarray) |
| 116 | + |
| 117 | + @property |
| 118 | + def shape(self): |
| 119 | + # object cast bc _ndarray.shape is npy_intp* |
| 120 | + return (<object>(self._ndarray)).shape |
| 121 | + |
| 122 | + @property |
| 123 | + def ndim(self) -> int: |
| 124 | + return self._ndarray.ndim |
| 125 | + |
| 126 | + @property |
| 127 | + def size(self) -> int: |
| 128 | + return self._ndarray.size |
| 129 | + |
| 130 | + @property |
| 131 | + def nbytes(self) -> int: |
| 132 | + return self._ndarray.nbytes |
| 133 | + |
| 134 | + def copy(self): |
| 135 | + # NPY_ANYORDER -> same order as self._ndarray |
| 136 | + res_values = cnp.PyArray_NewCopy(self._ndarray, cnp.NPY_ANYORDER) |
| 137 | + return self._from_backing_data(res_values) |
| 138 | + |
| 139 | + def delete(self, loc, axis=0): |
| 140 | + res_values = np.delete(self._ndarray, loc, axis=axis) |
| 141 | + return self._from_backing_data(res_values) |
| 142 | + |
| 143 | + def swapaxes(self, axis1, axis2): |
| 144 | + res_values = cnp.PyArray_SwapAxes(self._ndarray, axis1, axis2) |
| 145 | + return self._from_backing_data(res_values) |
| 146 | + |
| 147 | + # TODO: pass NPY_MAXDIMS equiv to axis=None? |
| 148 | + def repeat(self, repeats, axis: int = 0): |
| 149 | + if axis is None: |
| 150 | + axis = 0 |
| 151 | + res_values = cnp.PyArray_Repeat(self._ndarray, repeats, <int>axis) |
| 152 | + return self._from_backing_data(res_values) |
| 153 | + |
| 154 | + def reshape(self, *args, **kwargs): |
| 155 | + res_values = self._ndarray.reshape(*args, **kwargs) |
| 156 | + return self._from_backing_data(res_values) |
| 157 | + |
| 158 | + def ravel(self, order="C"): |
| 159 | + # cnp.PyArray_OrderConverter(PyObject* obj, NPY_ORDER* order) |
| 160 | + # res_values = cnp.PyArray_Ravel(self._ndarray, order) |
| 161 | + res_values = self._ndarray.ravel(order) |
| 162 | + return self._from_backing_data(res_values) |
| 163 | + |
| 164 | + @property |
| 165 | + def T(self): |
| 166 | + res_values = self._ndarray.T |
| 167 | + return self._from_backing_data(res_values) |
0 commit comments